連載
» 2015年07月01日 05時00分 UPDATE

Tech TIPS:Windowsのバッチファイル中で日付をファイル名に使用する

バッチファイル中で日付や時間をベースにしたファイル名を利用したい場合がある。このような用途では、環境変数の%date%や%time%を利用して、ファイル名を合成すればよい。ただし、ファイル名に使えない文字は取り除きつつ、日付と時刻の情報を抜き出すテクニックが必要になる。

[打越浩幸, 島田広道,デジタルアドバンテージ]
Tech TIPS
Windows Server Insider


「Tech TIPS」のインデックス

連載目次

対象OS:Windows 2000/Windows XP/Windows Vista/Windows 7/Windows 8/Windows 8.1/Windows 10/Windows Server 2003/Windows Server 2008/Windows Server 2008 R2/Windows Server 2012/Windows Server 2012 R2



解説

 バッチファイル中で、日付や時間をベースにしたファイル名を利用したい場合は少なくない。例えばシステムデータやユーザーファイルをバックアップし、バックアップ先のフォルダーやファイル名に、その日の日付を反映した名前(例:「systemconfig-20150701」や「user1-150701」など)を付けたいといった場合である。

 このような目的のためには、環境変数の「date」や「time」を使えばよい(環境変数として参照する場合はそれぞれ「%date%」「%time%」とする)。それぞれ、今日の日付と現在の時刻を文字列にして返してくれる。

C:\>echo %date%
2015/07/01

C:\>echo %time%
14:54:08.22



 だがこれらの変数の返す値には、「/」や「:」といった、ファイル名としては利用できない文字が含まれている。ファイル名を生成する場合にはこれらの文字を取り除き、数字の部分だけを使いたい。

 そこで本TIPSでは、バッチファイルでdateやtime変数から日付と時刻の情報を抜き出して利用するためのテクニックを紹介する。

設定方法

●環境変数から数字部分を抽出する

 dateやtime変数から、数字の部分だけを取り出すには、単に「%date%」「%time%」とするのではなく、変数値の部分文字列抽出用の修飾を行えばよい。

 具体的には、ある変数Vの、先頭(文字列の左端)からm番目の文字からn文字分を取り出すには、「%V:~m,n%」とする(mは0から始まる)。

 例えば変数Vの値が「ABCDEFGHIJKL」の場合、6文字目から2文字分取り出すには「%V:~5,2%」とすればよい(先頭文字は0番目と数えるので、「6」ではなく「5」を指定する)。

C:\>set V=ABCDEFGHIJKL

C:\>echo %V:~5,2%
FG



 nを省略すると、位置mから最後尾(文字列の右端)までとなる。例えば「%V:~5%」とすると、「FGHIJKL」となる。

 mを省略すると、先頭からn文字の文字列となる。例えば「%V:~,5%」とすると「ABCDE」となる。

 またmに負の数を指定すると、先頭ではなく、最後尾から数えた文字位置になる。例えば「%V:~-3%」とすると、最後の3文字「JKL」になる。

 さらに、nに負の数を指定すると、最後のn文字を除いた部分、すなわち位置mからn文字目の直前までの文字列となる。例えば「%V:~5,-3%」とすると、「FGHI」となる。

 まとめると、次のようになる。

書式 意味
%V% 変数Vの値全体 「%V%」 ⇒ 「ABCDEFGHIJKL」
%V:~m% m文字目から、最後まで 「%V:~5%」 ⇒ 「FGHIJKL」
%V:~m,n% m文字目から、n文字分 「%V:~5,2%」 ⇒ 「FG」
%V:~,n% 先頭から、n文字分 「%V:~,5%」 ⇒ 「ABCDE」
%V:~m,-n% m文字目から、最後のn文字分を除いたもの 「%V:~5,-2%」 ⇒ 「FGHIJ」
%V:~-m% 後ろからm文字目から、最後まで 「%V:~-5%」 ⇒ 「HIJKL」
%V:~-m,n% 後ろからm文字目から、n文字分 「%V:~-5,2%」 ⇒ 「HI」
%V:~-m,-n% 後ろからm文字目から、最後のn文字分を除いたもの 「%V:~-5,-2%」 ⇒ 「HIJ」
%V:s1=s2% 文字列s1を文字列s2に置換する。s2を省略すると、s1の削除になる 「%V:ABC=abc%」 ⇒ 「abcDEFGHIJKL」
「%V:ABC=%」 ⇒ 「DEFGHIJKL」
変数の部分文字列の抽出と置換
変数の値全体を参照するには「%V%」とする。また、変数名の修飾子として「:~<数値>」「:~<数値>,<数値>」「:~,<数値>」を付けることにより、文字列の一部分だけを取り出せる。修飾子の詳しい解説はコマンドプロンプト上で「set /?」を実行すると表示される。ここではVの値は「ABCDEFGHIJKL」としている。

●date環境変数から日付の数字だけを抽出する

 以上の書式を使えば、「2015/07/01」のような文字列の入ったdate変数から数字の部分だけを抜き出すには、

  • 年: 先頭から、4文字分
  • 月: 先頭より6文字目から、2文字分
  • 日: 先頭より9文字目から、2文字分

 すなわち、

%date:~0,4%%date:~5,2%%date:~8,2%



とすればよいことが分かるだろう(年と月と日の部分をそれぞれ抜き出して結合している)。

C:\>echo %date%
2015/07/01

C:\>echo %date:~0,4%%date:~5,2%%date:~8,2%
20150701



 なお、コントロールパネルの[地域と言語]アプレット(あるいは[地域と言語のオプション]、[地域のオプション])で、日本以外の地域を選択したり、あるいは日付と時刻の形式をデフォルトから変更したりすると、数字の位置が変わってしまう。すると日付や時刻が正しく抜き出せなくなることがあるので、注意が必要だ。

 本TIPSの方法を利用する場合は、「echo %date%」でどのような結果が得られるか、まず確認してから利用していただきたい。

Windows 2000のdate環境変数に注意

 本文では、「%date%」の結果が例えば「2015/07/01」という場合の文字列処理の方法を解説した。ところが(非常に古いOSである)Windows 2000では、「%date%」の結果が「2015/07/01」ではなく、「水 2015/07/01」というように、先頭に曜日を表す文字が含まれている。

 このような文字列の入ったdate変数から数字の部分だけを抜き出すには、

  • 年: 最後尾より10文字目から、4文字分
  • 月: 最後尾より5文字目から、2文字分
  • 日: 最後尾より2文字目から、2文字分

すなわち、

%date:~-10,4%%date:~-5,2%%date:~-2,2%



とすればよいことが分かる。

C:\>echo %date%
水 2015/07/01

C:\>echo %date:~-10,4%%date:~-5,2%%date:~-2,2%
20150701



 この方法であれば、Windows 2000のようにdate変数の先頭に曜日が入る場合でも、あるいはWindows XP以降のWindows OSのように曜日が入らない場合でも、そのまま利用できる。


●time環境変数から時刻の数字だけを抽出する

 日付の場合と同様に、時刻(時分秒)の場合にも少し注意点がある。

 午前0時から午前10時(00:00:59〜9:59:59)の場合、time変数が返す文字列の先頭には、「0」ではなく、空白文字が含まれている(「00」「01」「02」……「09」「10」「11」……ではなく、「 0」「 1」「 2」……「 9」「10」「11」……となる)。つまり時(0〜23)の数値はゼロサプレスされて表示されている。

 そのため、時間を取り出すために、単純に「%time:~0,2%%time:~3,2%%time:~6,2%」とすると、先頭に空白文字が入っている可能性がある。これをそのままファイル名やバッチファイルのパラメーターとして利用すると、空白文字によって引数の区切りとして扱われるなどの不具合が生じる可能性がある。

C:\>time 1:23

C:\>echo %time%
 1:23:04.29

C:\>time 12:34

C:\>echo %time%
12:34:01.60



 このような不具合を防ぐためには、time変数に含まれる空白文字を、最初に数字の0に置き換えておけばよいだろう。変数の置換は先の表にあるように、「%V:s1=s2%」とすればよい。ここでs1には空白1文字を、s2には「0」を指定する。

C:\>echo %time:~0,2%%time:~3,2%%time:~6,2%
 11204   ……置換しない場合は、このように先頭に空白文字が含まれる

C:\>set time2=%time: =0%   ……いったん一時変数に入れて置換する

C:\>echo %time2:~0,2%%time2:~3,2%%time2:~6,2%
011204   ……先頭に空白文字は含まれず、必ず数字が入る



 なお、「%time%」の内容をいったん変数time2に入れてから次の行で2桁ずつ取り出しているのは、文字列の置換と部分抽出を同時に行えないからである。

●実際の利用例(バックアップした日がすぐ分かるようにフォルダーをバックアップする)

 この手法を利用して、例えばrobocopyコマンドで過去のバックアップを残しつつ、特定のフォルダーをバックアップする例を説明しよう。

 バックアップの保存先としては、このバッチファイルを起動したドライブの「\Backup」というフォルダーの直下に、バックアップした日付を含む名前のサブフォルダーを作成して利用する。これにより過去のバックアップは上書きされずに別々のサブフォルダーに保存されていく。

 また、このサブフォルダーをどこか別のシステムへコピーして保存することを考え、サブフォルダー名にはサーバー名も含めるようにしている(ファイル名の最後に「-%COMPUTERNAME%」などを付けてコンピューター名を付加する)。これにより、どのシステムでいつバックアップしたかがすぐに分かるようになる。

※ファイル: backupcmd.cmd

setlocal

set drv=%cd:~0,1%
set dt=%date%
set FName=%drv%:\Backup\%dt:~-10,4%%dt:~-5,2%%dt:~-2,2%-%COMPUTERNAME%

robocopy c:\datafiles "%FName%" /mir

endlocal



 「set drv=%cd:~0,1%」は、カレントドライブを取り出すための指定である。タスクスケジューラーで自動起動する場合は、カレントドライブではなく、「C:」や「D:」など、特定のドライブを明示的に指定するのがよい。

 「set dt=%date%」で、いったんdate変数をdtという変数にコピーしているのは、date変数を3回参照している間に日付が変わってしまっても問題がないようにするためである。

 このテクニックはdate変数より、むしろtime変数を使う場合に有用だろう。なぜなら、処理に時間がかかるとtime変数の値はどんどん進んでしまい、不整合が生じる可能性があるからだ。

 なお、「%date%」を実行してから「%time%」を実行するまでの間に日付が変わる可能性もわずかながらある。それが心配なら、次のようにIF文を追加で実行して、「%date%」を再取得するとよいだろう。

set dt=%date%& set tm=%time%
if "%tm:~0,5%"==" 0:00" set dt=%date%

※00時00分の場合は、日付が前日の可能性があるので再取得する



●1日前の計算

 以上の例では今日の日付を取り出してフォルダー名の一部に用いている。しかし実際には、前日の日付が欲しい場合も少なくない。例えば前日分のログファイルを別のサーバーへコピーしたり、1カ月前のファイルを見つけ出して削除したり、といったケースが考えられる。

 だが残念なことに、1日前とか1カ月前を計算して、変数にセットする簡単な方法はない。

 一応「set /a」コマンドを使えば数値計算もできるので、日付部分を1日前に戻すといった操作も不可能ではない。しかし、月の初めや年の初め、うるう年の2月末日の処理なども考慮しなければならないので、非常に面倒である。

 あえてバッチファイルで書くとすると、次のようになるだろうか。

※ファイル:prevdate.cmd

setlocal

set dt=%date%
set yy=%dt:~-10,4%
set mm=%dt:~-5,2%
set dd=%dt:~-2,2%
echo 今日は%yy%年、%mm%月、%dd%日です。
echo.

rem 1日前の日付を計算する

set /a dd=1%dd%-101
set dd=00%dd%
set dd=%dd:~-2%
set /a ymod=%yy% %% 4

if %dd%==00 (
if %mm%==01 (set mm=12 & set dd=31 & set /a yy=%yy%-1)
if %mm%==02 (set mm=01 & set dd=31)
if %mm%==03 (set mm=02 & set dd=28 & if %ymod%==0 (set dd=29))
if %mm%==04 (set mm=03 & set dd=31)
if %mm%==05 (set mm=04 & set dd=30)
if %mm%==06 (set mm=05 & set dd=31)
if %mm%==07 (set mm=06 & set dd=30)
if %mm%==08 (set mm=07 & set dd=31)
if %mm%==09 (set mm=08 & set dd=31)
if %mm%==10 (set mm=09 & set dd=30)
if %mm%==11 (set mm=10 & set dd=31)
if %mm%==12 (set mm=11 & set dd=30)
)

echo 1日前は、%yy%年、%mm%月、%dd%日です。

endlocal



 だが、ここまでしてわざわざバッチファイルで計算するのは、あまり勧められない。n日前にするといった応用が利かないからだ。

 こういった場合はWSHやPowerShellで処理する方が簡単かもしれない。WSHを利用する方法については、TIPS「曜日や日付によって処理を切り替える(BAT File)」などを参考にしていただきたい。

■更新履歴

【2015/07/01】Windows 8/Windows 8.1/Windows 10プレビュー、およびWindows Server 2012/Windows Server 2012 R2での動作を確認しました。

【2011/08/26】「1日前の計算」のprevdate.batにて、日付が8日または9日のときにエラーが発生する不具合と、Windows 2000で年月日を正しく抽出できなかった不具合を修正しました。以上、お詫びして訂正いたします。また、Windows Server 2008/Windows 7/Windows Server 2008 R2での動作を確認しました。さらに、例として採りあげていたntbackupコマンドがWindows Vista以降で利用できなくなったため、代わりにrobocopyによるフォルダーバックアップの例に差し替えました。

【2007/10/12】%time%変数の取り扱いに関する注意点を追加しました。

【2004/05/05】当初、%date%変数から数字の部分を抜き出す方法として「%date:~0,4%%date:~5,2%%date:~8,2%」を紹介しておりましたが、Windows 2000環境では日付文字列の先頭に曜日が表示されるのでこれでは正しく動作しないことが判明しました。そこでいったん「%date:~-10%」として、数字部分だけを取得する方法に変更し、関連する解説文を追加・変更しました。お詫びして訂正させていただきます。

【2004/05/01】初版公開(対象はWindows 2000/Windows XP/Windows Server 2003)。


「Tech TIPS」のインデックス

Tech TIPS

Copyright© 1999-2015 Digital Advantage Corp. All Rights Reserved.

@IT Special

- PR -

TechTargetジャパン

Loading

ホワイトペーパー(TechTargetジャパン)

注目のテーマ

Focus

- PR -

転職/派遣情報を探す

【転職サーチ】SIer/Web企業/新規事業 スマホ開発で、あなたのキャリアを生かす

「派遣・フリーで働くメリット」とは? 活躍する派遣エンジニアの本音

RSSについて

アイティメディアIDについて

メールマガジン登録

@ITのメールマガジンは、 もちろん、すべて無料です。ぜひメールマガジンをご購読ください。