第8回　Functionプロシージャでユーザー独自の関数を定義する：基礎解説 演習方式で身につけるチェック式WSH超入門（3/3 ページ）

マーカーで隠れたところを選択してチェックしてみよう。

Option Explicit

'1から100までの間に含まれる素数を表示
Call ShowPrime(1, 100)
'1000から2000までの間に含まれる素数を表示
Call ShowPrime(1000, 2000)

'*********************************************************
'用途: 与えられた数値の範囲に含まれる素数を表示する
'受け取る値: intStart: 開始する数値(Integer)
'            intEnd: 終了する数値(Integer)
'戻り値: なし
'*********************************************************
Sub ShowPrime(intStart, intEnd)
    '開始と終了の値の大きさが逆だったら終了
    If intStart > intEnd Then
        Exit Sub
    End If

    Dim intCounter, intPrimeCount, strPrime
    strPrime = ""
    intPrimeCount = 0

    '開始の数値から終了の数値までループする
    For intCounter = intStart To intEnd
        ' intCounterが素数なら
        If IsPrime(intCounter) Then
            '出力文字列にその値を加える
            strPrime = strPrime & intCounter & ","
            '素数の数をインクリメント
            intPrimeCount = intPrimeCount + 1
            '整形のため、10個ごとに改行コードを入れる
            If intPrimeCount Mod 10 = 0 Then
                strPrime = strPrime & vbCrLf
            End If
        End If
    Next

    MsgBox intStart & "から" & intEnd & "までの素数：" & vbCrLf & _
           strPrime & vbCrLf & _
           "（" & intPrimeCount & "個）"
End Sub

'*********************************************************
'用途: 与えられた数値が素数かどうかを判定する
'受け取る値: intNumber: 判定する数値(Integer)
'戻り値: 与えられた数値の階乗(Boolean)
'*********************************************************
Function IsPrime(intNumber)
    '引数が1未満なら終了
    If intNumber < 1 Then
        IsPrime = False 'Falseを返す
        Exit Function
    End If

    Dim intCounter, intFactorCount
    intFactorCount = 0

    '1から引数の数値まで繰り返す
    For intCounter = 1 To intNumber
        '引数がカウンターの数値で割り切れる場合は
        If intNumber Mod intCounter = 0 Then
            '約数の数をインクリメントする
            intFactorCount = intFactorCount + 1
        End If
    Next

    '約数の数が2つならTrue、それ以外ならFalseを返す
    If intFactorCount = 2 Then
        IsPrime = True
    Else
        IsPrime = False
    End If
End Function