人体感知センサー×Webカメラで「サーバルーム簡易監視＆防犯システム」を作る：ラズパイ3＆Toradex、Windows 10 IoT Coreで楽しみながら検証するIoT実践入門（3）（3/4 ページ）

Imports Windows.Devices.Enumeration
Imports Windows.Devices.Gpio　　'' PIRセンサー使用のために追加した名前空間
Imports Windows.Media.Capture
Imports Windows.UI.Popups
Public NotInheritable Class MainPage
    Inherits Page
    Private myMediaCapture As MediaCapture
    Private myCamera As DeviceInformationCollection
    Private Const GPIO_PI As Integer = 5　　'' PIRセンサー使用のために追加したメンバー定数変数
    Private pin As GpioPin　　'' PIRセンサー使用のために追加したメンバー変数
    Private Async Sub MainPage_Loaded(sender As Object, e As RoutedEventArgs) Handles Me.Loaded
        Await DataShow()
        Await initGpio()　　'' PIRセンサー使用のために追加したプロシージャを読み込む
    End Sub
    Private Async Function DataShow() As Task
        Try
            ComboBox1.Items.Clear()
            myCamera = Await DeviceInformation.FindAllAsync(DeviceClass.VideoCapture)
            For i As Integer = 0 To myCamera.Count - 1
                Dim CameraInfo As DeviceInformation = myCamera(i)
                ComboBox1.Items.Add(CameraInfo.Name)
            Next
            ComboBox1.SelectedIndex = 0
            myMediaCapture = New MediaCapture
            Await myMediaCapture.InitializeAsync()
            CaptureElement1.Source = myMediaCapture
            ''Await myMediaCapture.StartPreviewAsync
        Catch ex As Exception
            ErrorShow()
        End Try
    End Function
'' PIRセンサー使用のためにGPIOの初期化処理
    Private Async Function initGpio() As Task
        Dim gpio = GpioController.GetDefault
        If gpio Is Nothing = True Then
            Exit Function
        End If
        pin = gpio.OpenPin(GPIO_PI)
        If pin.IsDriveModeSupported(GpioPinDriveMode.InputPullUp) Then
            pin.SetDriveMode(GpioPinDriveMode.InputPullUp)
        Else
            pin.SetDriveMode(GpioPinDriveMode.Input)
        End If
        Await Task.Delay(1000)
        AddHandler pin.ValueChanged, AddressOf Pin_ValueChanged
    End Function
'' PIRセンサーが反応したときの処理
    Private Async Sub Pin_ValueChanged(sender As GpioPin, e As GpioPinValueChangedEventArgs)
        If e.Edge = GpioPinEdge.RisingEdge Then
            Await myMediaCapture.StartPreviewAsync
        End If
        If e.Edge = GpioPinEdge.FallingEdge Then
            Await myMediaCapture.StopPreviewAsync
        End If
    End Sub
    Private Async Sub ErrorShow()
        Dim message As New MessageDialog("カメラが装備されておりません")
        Await message.ShowAsync
        Exit Sub
    End Sub
End Class