XmlSerializerを使ってシリアライズ／デシリアライズするには？［C#／VB］：.NET TIPS

Imports System.Console
Imports System.IO
Imports System.Text
Imports System.Xml.Serialization

' シリアライズ対象のクラス
Public Class Sample
  Public Property Id As Integer
  Public Property Text As String
End Class

Module Module1
  Sub Main()
    ' シリアライズ先のファイル
    Const xmlFile As String = ".\Sample.xml"
    ' シリアライズするオブジェクト
    Dim obj = New Sample With {.Id = 7, .Text = "＠IT"} ' （1）

    ' シリアライズする
    Dim xmlSerializer1 = New XmlSerializer(GetType(Sample))
    Using streamWriter = New StreamWriter(xmlFile, False, Encoding.UTF8)
      xmlSerializer1.Serialize(streamWriter, obj)
      streamWriter.Flush()
    End Using
    ' 書き出されたファイルの内容（一部に改行を入れている）：
    ' <?xml version="1.0" encoding="utf-8"?>
    ' <Sample xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance"
    '         xmlns:xsd="http://www.w3.org/2001/XMLSchema">
    '   <Id>7</Id>
    '   <Text>＠IT</Text>
    ' </Sample>

    ' デシリアライズする
    Dim xmlSerializer2 = New XmlSerializer(GetType(Sample))
    Dim result As Sample
    Dim xmlSettings = New System.Xml.XmlReaderSettings() _
    With {
      .CheckCharacters = False ' （2）
    }
    Using streamReader = New StreamReader(xmlFile, Encoding.UTF8)
      Using xmlReader = System.Xml.XmlReader.Create(streamReader, xmlSettings)
        result = CType(xmlSerializer2.Deserialize(xmlReader), Sample) ' （3）
      End Using
    End Using
    WriteLine($"{result.Id}, {result.Text}")
    ' 出力：7, ＠IT

#If DEBUG Then
    ReadKey()
#End If
  End Sub
End Module

' シリアライズするオブジェクト
' Dim obj = New Sample With {.Id = 7, .Text = "＠IT"} ' （1）
' ↓
Dim obj = New Sample With {.Id = 7, .Text = $"＠{ChrW(&H1A)}IT"}

Dim xmlSettings = New System.Xml.XmlReaderSettings() _
'With {
'  .CheckCharacters = False  ' （2）
'}

Imports System.IO
Imports System.Text
Imports System.Xml.Serialization

……省略……

' 排他ロックに使うSemaphoreSlimオブジェクト
' （プロセス間の排他が必要なときはSemaphoreオブジェクトに変える）
Private _semaphore As System.Threading.SemaphoreSlim _
  = New System.Threading.SemaphoreSlim(1, 1)

'シリアライズする
Async Function SerializeAsync(Of T)(data As T, filePath As String) As Task
  Await _semaphore.WaitAsync() ' ロックを取得する
  Try
    Dim XmlSerializer = New XmlSerializer(GetType(T))
    Using streamWriter = New StreamWriter(filePath, False, Encoding.UTF8)
      Await Task.Run(Sub() XmlSerializer.Serialize(streamWriter, data))
      Await streamWriter.FlushAsync()  ' .NET Framework 4.5以降
    End Using
  Finally
    _semaphore.Release() ' ロックを解放する
  End Try
End Function

' デシリアライズする
Async Function DeserializeAsync(Of T)(filePath As String) As Task(Of T)
  Await _semaphore.WaitAsync() ' ロックを取得する
  Try
    Dim xmlSerializer = New XmlSerializer(GetType(T))
    Dim xmlSettings = New System.Xml.XmlReaderSettings() _
    With {
      .CheckCharacters = False
    }
    Using streamReader = New StreamReader(filePath, Encoding.UTF8)
      Using xmlReader = System.Xml.XmlReader.Create(streamReader, xmlSettings)
        Return Await Task.Run(Function() CType(xmlSerializer.Deserialize(xmlReader), T))
      End Using
    End Using
  Finally
    _semaphore.Release() ' ロックを解放する
  End Try
End Function