日付の年号を表示するには？［独自テーブル参照編］：.NET TIPS

Imports System.Console

Public Module JapaneseEraTable
  ' 年号テーブル
  Private _eraTable As DataTable

  ' 静的コンストラクタ：テーブルを初期化する
  Sub New()
    _eraTable = New DataTable()
    _eraTable.Columns.Add("StartDate", GetType(DateTime))
    _eraTable.Columns.Add("Name", GetType(String))
    _eraTable.Columns.Add("EnglishName", GetType(String))

    ' 必ず日付の降順に並べる
    _eraTable.Rows.Add(New DateTime(1989, 1, 8), "平成", "Heisei")
    _eraTable.Rows.Add(New DateTime(1926, 12, 25), "昭和", "Showa")
    _eraTable.Rows.Add(New DateTime(1912, 7, 30), "大正", "Taisho")
    _eraTable.Rows.Add(New DateTime(1868, 1, 25), "明治", "Meiji")
  End Sub
End Module

Public Module JapaneseEraTable
  ……省略……

  Private Function GetEraRow(theDate As DateTime) As DataRow
    ' 新しい元号から順に見ていく
    For i As Integer = 0 To (_eraTable.Rows.Count - 1)
      Dim row = _eraTable.Rows(i)
      ' その日以前の元号開始日が見つかったら、それがその日の元号
      If (CType(row("StartDate"), DateTime) <= theDate) Then
        Return row
      End If
    Next
    Throw New ArgumentOutOfRangeException()
  End Function
End Module

Public Module JapaneseEraTable
  ……省略……

  ' 日付から年号の文字列を得る
  Public Function GetName(theDate As DateTime) As String
    Return CStr(GetEraRow(theDate)("Name"))
  End Function
  ' 日付から年号の頭文字を得る
  Public Function GetFirstLetter(theDate As DateTime) As String
    Return GetName(theDate).Substring(0, 1)
  End Function
  ' 日付から年号の文字列を得る（ローマ字）
  Public Function GetEnglishName(theDate As DateTime) As String
    Return CStr(GetEraRow(theDate)("EnglishName"))
  End Function
  ' 日付から年号の頭文字を得る（ローマ字）
  Public Function GetEnglishFirstLetter(theDate As DateTime) As String
    Return GetEnglishName(theDate).Substring(0, 1)
  End Function
End Module

Public Module JapaneseEraTable
  ……省略……

  ' 日付から和暦の年を計算する
  Public Function GetEraYear(theDate As DateTime) As Integer
    Dim eraStartDate = CType(GetEraRow(theDate)("StartDate"), DateTime)
    Return theDate.Year - eraStartDate.Year + 1
  End Function
End Module

Dim d1 = New DateTime(1926, 12, 24, 23, 59, 59)
Dim n1 As String = JapaneseEraTable.GetName(d1)
Dim y1 As Integer = JapaneseEraTable.GetEraYear(d1)
WriteLine($"{d1:yyyy/MM/dd} {n1}{y1:00}年{d1:MM月dd日}")
' 出力：1926/12/24 大正15年12月24日

Dim d2 = New DateTime(1926, 12, 25)
Dim n2 As String = JapaneseEraTable.GetFirstLetter(d2)
Dim y2 As Integer = JapaneseEraTable.GetEraYear(d2)
WriteLine($"{d2:yyyy/MM/dd} {n2}{y2}年{d2:M月d日}")
' 出力：1926/12/25 昭1年12月25日

Dim d3 = New DateTime(1989, 1, 8)
Dim n3 As String = JapaneseEraTable.GetEnglishName(d3)
Dim y3 As Integer = JapaneseEraTable.GetEraYear(d3)
WriteLine($"{d3:yyyy/MM/dd} {n3}{y3:00}/{d3:MM/dd}")
' 出力：1989/01/08 Heisei01/01/08

Dim d4 = New DateTime(2019, 5, 1)
Dim n4 As String = JapaneseEraTable.GetEnglishFirstLetter(d4)
Dim y4 As Integer = JapaneseEraTable.GetEraYear(d4)
WriteLine($"{d4:yyyy/MM/dd} {n4}{y4}/{d4:M/d}")
' 出力：2019/05/01 H31/5/1

Public Class JapaneseEra
  ' 元号の開始日
  Public ReadOnly Property StartDate As DateTime
  ' 元号の名称
  Public ReadOnly Property Name As String
  ' 元号の頭文字
  Public ReadOnly Property FirstLetter As String
  ' ローマ字表記の名称
  Public ReadOnly Property EnglishName As String
  ' ローマ字表記の頭文字
  Public ReadOnly Property EnglishFirstLetter As String

  ' コンストラクタ
  Private Sub New(startDate As DateTime, name As String, englishName As String)
    Me.StartDate = startDate
    Me.Name = name
    Me.FirstLetter = Me.Name.Substring(0, 1)
    Me.EnglishName = englishName
    Me.EnglishFirstLetter = Me.EnglishName.Substring(0, 1)
  End Sub
End Class

Public Class JapaneseEra
  ……省略……

  ' 静的プロパティ：JapaneseEraインスタンスを収めた読み取り専用のリスト
  ' ・順序が保証されるコレクションを使う
  ' ・必ず降順に並べる
  Public Shared ReadOnly Property Table As IList(Of JapaneseEra) _
    = New List(Of JapaneseEra) From
    {
      New JapaneseEra(New DateTime(1989, 1, 8), "平成", "Heisei"),
      New JapaneseEra(New DateTime(1926, 12, 25), "昭和", "Showa"),
      New JapaneseEra(New DateTime(1912, 7, 30), "大正", "Taisho"),
      New JapaneseEra(New DateTime(1868, 1, 25), "明治", "Meiji")
    } _
    .AsReadOnly() ' リストの内容を変更できないようにする
End Class

Public Class JapaneseEra
  ……省略……

  ' 日付に該当するJapaneseEraインスタンスを得る
  Public Shared Function GetEra(theDate As DateTime) As JapaneseEra
    Return Table.FirstOrDefault(Function(era) era.StartDate <= theDate)
  End Function
End Class

Public Class JapaneseEra
  ……省略……

  ' 日付から和暦の年を得る
  Public Function GetEraYear(theDate As DateTime) As Integer
    Return theDate.Year - Me.StartDate.Year + 1
  End Function
End Class

Dim d1 = New DateTime(1926, 12, 24, 23, 59, 59)
Dim e1 = JapaneseEra.GetEra(d1)
WriteLine($"{d1:yyyy/MM/dd} {e1.Name}{e1.GetEraYear(d1):00}年{d1:MM月dd日}")
' 出力：1926/12/24 大正15年12月24日

Dim d2 = New DateTime(1926, 12, 25)
Dim e2 = JapaneseEra.GetEra(d2)
WriteLine($"{d2:yyyy/MM/dd} {e2.FirstLetter}{e2.GetEraYear(d2)}年{d2:M月d日}")
' 出力：1926/12/25 昭1年12月25日

Dim d3 = New DateTime(1989, 1, 8)
Dim e3 = JapaneseEra.GetEra(d3)
WriteLine($"{d3:yyyy/MM/dd} {e3.EnglishName}{e3.GetEraYear(d3):00}/{d3:MM/dd}")
' 出力：1989/01/08 Heisei01/01/08

Dim d4 = New DateTime(2019, 5, 1)
Dim e4 = JapaneseEra.GetEra(d4)
WriteLine($"{d4:yyyy/MM/dd} {e4.EnglishFirstLetter}{e4.GetEraYear(d4)}/{d4:M/d}")
' 出力：2019/05/01 H31/5/1