祝日を求めるには？［C#、VB］：.NET TIPS

Public Class Holiday
  Public Property [Date] As DateTime ' 日付
  Public Property Kind As HolidayKind ' 種類
  Public Property Name As String ' 名称
  Public Property Definition As String ' 祝日の定義
End Class

Public Enum HolidayKind
  平日 = 0
  国民の祝日 = 1
  振替休日 = 2
  国民の休日 = 3
End Enum

Sub Main(args As String())
  ' 祝日を計算する年
  Const Year As Integer = 2015

  ' 祝日を格納するコレクション
  Dim holidays As SortedDictionary(Of DateTime, Holiday) _
    = New SortedDictionary(Of DateTime, Holiday)()

  ' ここに祝日を求めるロジックを書く

  ' 祝日を出力する
  Console.WriteLine("{0}年の休日", Year)
  For Each d In holidays.Values
    Console.WriteLine("{0:MM/dd(ddd)} {1}（{2}、{3}）",
                      d.Date, d.Name, d.Definition, d.Kind)
  Next
  Console.WriteLine()

#If DEBUG Then
  ' デバッグ実行時にコンソールがすぐに閉じてしまうのを防ぐ
  Console.ReadKey()
#End If
End Sub

' 元日：1月1日
Dim 元日 = New Holiday() With
        {
          .Date = New DateTime(Year, 1, 1),
          .Kind = HolidayKind.国民の祝日,
          .Name = "元日", .Definition = "1月1日"
        }
holidays.Add(元日.Date, 元日)

……省略……

' 山の日：8月11日 (2016年より)
If (2016 <= Year) Then
  Dim 山の日 = New Holiday() With
          {
            .Date = New DateTime(Year, 8, 11),
            .Kind = HolidayKind.国民の祝日,
            .Name = "山の日", .Definition = "8月11日"
          }
  holidays.Add(山の日.Date, 山の日)
End If

……省略……

Private Function GetNthMonday(nth As Integer, year As Integer, month As Integer) As DateTime

  ' 指定された月の日数
  Dim days As Integer = DateTime.DaysInMonth(year, month)

  ' 指定された月の全ての日から、月曜日だけを取り出す
  Dim allMondays As IEnumerable(Of DateTime) _
    = Enumerable.Range(1, days) _
      .Select(Function(d) New DateTime(year, month, d)) _
      .Where(Function(dt) dt.DayOfWeek = DayOfWeek.Monday)
  ' Enumerable.Rangeで1日〜月末の日付（int型のコレクション）を作り
  ' SelectでDateTime型のコレクションに変換して
  ' Whereでそこから月曜日だけを取り出す

  ' N番目の月曜日を求める
  Return allMondays.ElementAt(nth - 1)
End Function

' 成人の日：1月の第2月曜日
Dim 成人の日 = New Holiday() With
        {
          .Date = GetNthMonday(2, Year, 1),
          .Kind = HolidayKind.国民の祝日,
          .Name = "成人の日", .Definition = "1月の第2月曜日"
        }
holidays.Add(成人の日.Date, 成人の日)

……省略……

' 春分日を求める（2099年まで有効な実験式）
Private Function CalcVernalEquinoxDay(year As Integer) As DateTime

  ' 1. 2000年の太陽の春分点通過日
  Dim 基準日 As Double = 20.69115

  ' 2. 春分点通過日の移動量＝（西暦年−2000年）×0.242194
  Dim 移動量 As Double = (year - 2000) * 0.242194

  ' 3. 閏年によるリセット量＝INT｛（西暦年−2000年）/ 4｝
  Dim 閏年補正 As Integer = CType(Int((year - 2000) / 4.0), Integer)

  ' 求める年の春分日＝INT｛（1）＋（2）−（3）｝
  Dim 春分日 As Integer = CType(Int(基準日 + 移動量 - 閏年補正), Integer)

  Return New DateTime(year, 3, 春分日)
End Function

' 秋分日を求める（2099年まで有効な実験式）
Private Function CalcAutumnalEquinoxDay(year As Integer) As DateTime

  ' 1. 2000年の太陽の秋分点通過日
  Dim 基準日 As Double = 23.09 ' 秋分点の揺らぎ補正済みの値

  ' 2. 秋分点通過日の移動量＝（西暦年−2000年）×0.242194
  Dim 移動量 As Double = (year - 2000) * 0.242194

  ' 3. 閏年によるリセット量＝INT｛（西暦年−2000年）/ 4｝
  Dim 閏年補正 As Integer = CType(Int((year - 2000) / 4.0), Integer)

  ' 求める年の秋分日＝INT｛（1）＋（2）−（3）｝
  Dim 秋分日 As Integer = CType(Int(基準日 + 移動量 - 閏年補正), Integer)

  Return New DateTime(year, 9, 秋分日)
End Function

' 春分の日
Dim 春分の日 = New Holiday() With
        {
          .Date = CalcVernalEquinoxDay(Year),
          .Kind = HolidayKind.国民の祝日,
          .Name = "春分の日", .Definition = "春分日"
        }
holidays.Add(春分の日.Date, 春分の日)

' 秋分の日
Dim 秋分の日 = New Holiday() With
        {
          .Date = CalcAutumnalEquinoxDay(Year),
          .Kind = HolidayKind.国民の祝日,
          .Name = "秋分の日", .Definition = "秋分日"
        }
holidays.Add(秋分の日.Date, 秋分の日)

' 振替休日を全て求める
Private Function GetSubstituteHolidays(
  holidays As SortedDictionary(Of DateTime, Holiday)) As IEnumerable(Of Holiday)

  ' 振替休日を格納するためのコレクション
  Dim substituteHolidays As List(Of Holiday) = New List(Of Holiday)()

  ' これまでに求めた祝日を全部チェックする
  For Each holiday In holidays.Values
    If (holiday.Date.DayOfWeek <> DayOfWeek.Sunday) Then
      Continue For ' 日曜でなければ除外する
    End If

    ' 翌日（＝月曜日）を仮に振替休日とする
    Dim substitute As DateTime = holiday.Date.AddDays(1.0)

    ' その日がすでに祝日ならば振替休日はさらにその翌日
    While (holidays.ContainsKey(substitute))
      substitute = substitute.AddDays(1.0)
    End While

    ' 見つかった振替休日をコレクションに追加する
    Dim substituteHoliday = New Holiday() With
    {
      .Date = substitute,
      .Kind = HolidayKind.振替休日,
      .Name = "振替休日",
      .Definition = String.Format("{0}の振替休日", holiday.Name)
    }
    substituteHolidays.Add(substituteHoliday)
  Next
  Return substituteHolidays
End Function

Dim substituteHolidays = GetSubstituteHolidays(holidays)
For Each s In substituteHolidays
  holidays.Add(s.Date, s)
Next

' 国民の休日を全て求める
Private Function GetSandwichedHolidays(
  holidays As SortedDictionary(Of DateTime, Holiday)) As IEnumerable(Of Holiday)

  Dim sandwichedHolidays As List(Of Holiday) = New List(Of Holiday)()

  ' これまでに求めた祝日を全部チェックする
  For Each holiday0 In holidays.Values
    If (holiday0.Kind <> HolidayKind.国民の祝日) Then
      Continue For ' その休日が国民の祝日でなければ除外する
    End If

    Dim day0 = holiday0.Date

    Dim day2 = day0.AddDays(2.0) ' 2日後
    If (Not holidays.ContainsKey(day2)) Then
      Continue For ' 2日後が祝日でないときは除外する
    End If
    Dim holiday2 = holidays(day2)
    If (holiday2.Kind <> HolidayKind.国民の祝日) Then
      Continue For ' 2日後が祝日であっても国民の祝日でなければ除外する
    End If

    Dim day1 = day0.AddDays(1.0) ' 1日後=国民の祝日で挟まれた日
    If (day1.DayOfWeek = DayOfWeek.Sunday) Then
      Continue For ' その日が日曜（＝もともと休日）のときは除外する
    End If
    If (holidays.ContainsKey(day1)) Then
      Continue For ' その日がすでに祝日のときは除外する
    End If

    ' 見つかった国民の休日をコレクションに追加する
    Dim sandwichedHoliday = New Holiday() With
    {
      .Date = day1,
      .Kind = HolidayKind.国民の休日,
      .Name = "国民の休日",
      .Definition = String.Format("{0}と{1}の間の日", holiday0.Name, holiday2.Name)
    }
    sandwichedHolidays.Add(sandwichedHoliday)
  Next
  Return sandwichedHolidays
End Function

Dim sandwichedHolidays = GetSandwichedHolidays(holidays)
For Each s In sandwichedHolidays
  holidays.Add(s.Date, s)
Next