指定した日の曜日を取得するには？［C#／VB］：.NET TIPS

' 例：2017年10月5日 木曜日
Dim theDay = New DateTime(2017, 10, 5)

' DateTime構造体のToStringメソッドを使う
Dim 長い曜日 As String = theDay.ToString("dddd")
Dim 短い曜日 As String = theDay.ToString("ddd")
Console.WriteLine($"長い曜日={長い曜日}、短い曜日={短い曜日}")
' 出力：長い曜日=木曜日、短い曜日=木

' StringクラスのFormatメソッドを使う
Dim 長い曜日2 As String = String.Format("{0:dddd}", theDay)
Dim 短い曜日2 As String = String.Format("{0:ddd}", theDay)
Console.WriteLine($"長い曜日={長い曜日2}、短い曜日={短い曜日2}")
' 出力：長い曜日=木曜日、短い曜日=木

' 例：2017年10月5日 木曜日
Dim theDay = New DateTime(2017, 10, 5)

' 英語のカルチャー
Dim culture = System.Globalization.CultureInfo.GetCultureInfo("en-US")

' DateTime構造体のToStringメソッドを使う
Dim longDayOfTheWeek As String = theDay.ToString("dddd", culture)
Dim shortDayOfTheWeek As String = theDay.ToString("ddd", culture)
Console.WriteLine($"長い曜日={longDayOfTheWeek}、短い曜日={shortDayOfTheWeek}")
' 出力：長い曜日=Thursday、短い曜日=Thu

' StringクラスのFormatメソッドを使う
Dim longDayOfTheWeek2 As String = String.Format(culture, "{0:dddd}", theDay)
Dim shortDayOfTheWeek2 As String = String.Format(culture, "{0:ddd}", theDay)
Console.WriteLine($"長い曜日={longDayOfTheWeek2}、短い曜日={shortDayOfTheWeek2}")
' 出力：長い曜日=Thursday、短い曜日=Thu

Dim 曜日名配列 As String() = {"Su", "M", "Tu", "W", "Th", "F", "Sa"}

' 例：2017年10月5日 木曜日
Dim theDay = New DateTime(2017, 10, 5)

'  DayOfWeekを使う
Dim dow As DayOfWeek = theDay.DayOfWeek ' 日曜=0〜土曜=6
Dim 独自の曜日名 As String = 曜日名配列(dow)
Console.WriteLine($"独自の曜日名={独自の曜日名}")
' 出力：独自の曜日名=Th

' Weekday関数を使う
Dim wd As Integer = Weekday(theDay) ' 日曜=1〜土曜=7
Dim 独自の曜日名2 As String = 曜日名配列(wd - 1)
Console.WriteLine($"独自の曜日名（Weekday関数使用）={独自の曜日名2}")
' 出力：独自の曜日名（Weekday関数使用）=Th

' 太陰太陽暦を使って六曜を求める
Dim 六曜名配列 As String() = {"大安", "赤口", "先勝", "友引", "先負", "仏滅"}

' 例：2017年10月5日 木曜日
Dim theDay = New DateTime(2017, 10, 5)

Dim 旧暦 = New System.Globalization.JapaneseLunisolarCalendar()
Dim 旧暦の月 As Integer = 旧暦.GetMonth(theDay)
Dim 旧暦の日 As Integer = 旧暦.GetDayOfMonth(theDay)

' 閏月を取得
Dim 旧暦元日 As DateTime = 旧暦.AddDays(theDay, 1 - 旧暦.GetDayOfYear(theDay))
Dim 閏月 As Integer = 旧暦.GetLeapMonth(旧暦.GetYear(旧暦元日), 旧暦.GetEra(旧暦元日))
' 2017年であれば、閏月=6 が返る。6番目の月が閏月、すなわち「閏5月」となる。
' 閏月のない年では、閏月 = 0 が返る。

' 閏月がある場合の旧暦月の補正
If ((閏月 > 0) AndAlso (旧暦の月 >= 閏月)) Then
  旧暦の月 -= 1
End If

' 六曜を算出
Dim 六曜 As String = 六曜名配列((旧暦の月 + 旧暦の日) Mod 6)

Console.Write($"{theDay:yyyy年M月d日}は")
Console.WriteLine($"旧暦{旧暦の月}月{旧暦の日}日（{六曜}）")
' 出力：2017年10月5日は旧暦8月16日（大安）