コンボボックスの右クリックの貼り付けイベント取得について

Option Strict On

Public Class ExactComboBox
    Inherits System.Windows.Forms.ComboBox

  #Region "　コンポーネント デザイナで生成されたコード　"

    Private components As System.ComponentModel.IContainer

    Public Sub New()
        MyBase.New()
        Me.components = New System.ComponentModel.Container()
    End Sub

    Protected Overloads Overrides Sub Dispose(ByVal disposing As Boolean)
        If disposing = True Then
            If Not Me.components Is Nothing Then
                Me.components.Dispose()
            End If
        End If

        MyBase.Dispose(disposing)
    End Sub
  
  #End Region

  #Region "　P/Invoke - GetComboBox 関数　"

    <System.Runtime.InteropServices.DllImport("USER32.DLL")> _
    Private Shared Function GetComboBoxInfo( _
        ByVal comboBoxHandle As System.IntPtr, _
        ByRef pComboBoxInfo  As ComboBoxInfo) As Boolean
    End Function

  #End Region

  #Region "　ComboBoxInfo 構造体　"

    <System.Runtime.InteropServices.StructLayout(System.Runtime.InteropServices.LayoutKind.Sequential)> _
    Private Structure ComboBoxInfo
        Public Size           As Integer
        Public RectItem       As System.Drawing.Rectangle
        Public RectButton     As System.Drawing.Rectangle
        Public ButtonState    As Integer
        Public ComboBoxHandle As System.IntPtr
        Public EditBoxHandle  As System.IntPtr
        Public ListBoxHandle  As System.IntPtr
    End Structure

  #End Region

  #Region "　EditBoxWindow クラス　"

    Private Class EditBoxWindow
        Inherits System.Windows.Forms.NativeWindow

        Public Sub New(ByVal parentComboBox As ComboBox)
            AddHandler parentComboBox.HandleDestroyed, AddressOf Me.OnHandleDestroyed
        End Sub

        Private Sub OnHandleDestroyed(ByVal sender As Object, ByVal e As System.EventArgs)
            Me.ReleaseHandle()
        End Sub

        <System.Security.Permissions.PermissionSetAttribute(System.Security.Permissions.SecurityAction.Demand)> _
        Protected Overrides Sub WndProc(ByRef m As Message)
            Const WM_PASTE As Integer = &H0302

            Select Case m.Msg
                Case WM_PASTE
                    MessageBox.Show("WM_PASTE")
            End Select

            MyBase.WndProc(m)
        End Sub

    End Class

  #End Region

  #Region "　OnHandleCreated メソッド (Override)　"

    Protected Overrides Sub OnHandleCreated(ByVal e As System.EventArgs)
        Dim tComboBoxInfo As New ComboBoxInfo()

        tComboBoxInfo.Size = System.Runtime.InteropServices.Marshal.SizeOf(tComboBoxInfo)

        If GetComboBoxInfo(Me.Handle, tComboBoxInfo) = False Then
            Return
        End If

        If tComboBoxInfo.EditBoxHandle.Equals(System.IntPtr.Zero) Then
            Return
        End If

        Dim hEditBoxWindow As New EditBoxWindow(Me)
        hEditBoxWindow.AssignHandle(tComboBoxInfo.EditBoxHandle)
    End Sub

  #End Region

End Class