クラス内部で別スレッドからメインスレッドにマーシャリングする方法

'Form1.vb
'デザイナでButton1とListBox1を貼り付けてください
Public Class Form1
    Inherits System.Windows.Forms.Form

#Region " Windows フォーム デザイナで生成されたコード "
    '省略
#End Region

    Private WithEvents c1 As New Class1

    Private Sub Button1_Click( _
        ByVal sender As System.Object, _
        ByVal e As System.EventArgs _
    ) Handles Button1.Click
        c1.Start()
    End Sub

    Private Sub c1_Progress( _
        ByVal sender As Object, _
        ByVal e As Class1.ProgressEventArgs _
    ) Handles c1.Progress
        Me.Invoke( _
            New AddListItemDelegate(AddressOf AddListItem), _
            New Object() {e.Message})
        'できれば、次のようにフォーム側ではInvokeをしなくてもよいようにしたい
        'AddListItem(e.Message)
    End Sub

    Private Delegate Sub AddListItemDelegate(ByVal message As String)

    Private Sub AddListItem(ByVal message As String)
        ListBox1.Items.Add(Threading.Thread.CurrentThread.Name & ":" & message)
    End Sub

End Class

'Class1.vb
Public Class Class1

    'スレッドオブジェクト
    Private _SubThread As Threading.Thread

    '別スレッドの処理を開始する
    Public Sub Start()
        'メインスレッドに名前を付ける
        Threading.Thread.CurrentThread.Name = "メインスレッド"
        '別スレッドを開始する
        _SubThread = New Threading.Thread( _
            New Threading.ThreadStart(AddressOf SubThreadProcess))
        _SubThread.Name = "サブスレッド"
        _SubThread.Start()
    End Sub

    '別スレッドで実行する処理
    Private Sub SubThreadProcess()
        '処理1
        Threading.Thread.Sleep(1000)
        OnProgress("処理1が終了しました。")     'この処理をメインスレッドで実行したい
        '処理2
        Threading.Thread.Sleep(1000)
        OnProgress("処理2が終了しました。")     'この処理をメインスレッドで実行したい
        '処理3
        Threading.Thread.Sleep(1000)
        OnProgress("処理3が終了しました。")     'この処理をメインスレッドで実行したい
    End Sub

    '処理の途中経過を報告するイベント
    Public Event Progress(ByVal sender As Object, ByVal e As ProgressEventArgs)

    'Progressイベントを発生させる
    Private Sub OnProgress(ByVal message As String)
        RaiseEvent Progress(Me, New ProgressEventArgs(message))
    End Sub

    'Progressイベントのイベント変数クラス
    Public Class ProgressEventArgs
        Inherits EventArgs

        Private _message As String

        Public ReadOnly Property Message() As String
            Get
                Return _message
            End Get
        End Property

        Public Sub New(ByVal message As String)
            _message = message
        End Sub

    End Class

End Class

'Form1.vb
'デザイナでButton1とListBox1を貼り付けてください
Public Class Form1
    Inherits System.Windows.Forms.Form

#Region " Windows フォーム デザイナで生成されたコード "
    '省略
#End Region

    Private WithEvents c1 As New Class1

    Private Sub Button1_Click( _
        ByVal sender As System.Object, _
        ByVal e As System.EventArgs _
    ) Handles Button1.Click
        c1.SynchronizingObject = Me
        c1.Start()
    End Sub

    Private Sub c1_Progress( _
        ByVal sender As Object, _
        ByVal e As Class1.ProgressEventArgs _
    ) Handles c1.Progress
        'Me.Invoke( _
        '    New AddListItemDelegate(AddressOf AddListItem), _
        '    New Object() {e.Message})
        'できれば、次のようにフォーム側ではInvokeをしなくてもよいようにしたい
        AddListItem(e.Message)
    End Sub

    Private Delegate Sub AddListItemDelegate(ByVal message As String)

    Private Sub AddListItem(ByVal message As String)
        ListBox1.Items.Add(Threading.Thread.CurrentThread.Name & ":" & message)
    End Sub

End Class

'Class1.vb
Public Class Class1

    'スレッドオブジェクト
    Private _SubThread As Threading.Thread

    'マーシャリング用オブジェクト
    Private _SynchronizingObject As System.ComponentModel.ISynchronizeInvoke

    Public Property SynchronizingObject() As System.ComponentModel.ISynchronizeInvoke
        Get
            Return _SynchronizingObject
        End Get
        Set(ByVal Value As System.ComponentModel.ISynchronizeInvoke)
            _SynchronizingObject = Value
        End Set
    End Property

    '別スレッドの処理を開始する
    Public Sub Start()
        'メインスレッドに名前を付ける
        Threading.Thread.CurrentThread.Name = "メインスレッド"
        '別スレッドを開始する
        _SubThread = New Threading.Thread( _
            New Threading.ThreadStart(AddressOf SubThreadProcess))
        _SubThread.Name = "サブスレッド"
        _SubThread.Start()
    End Sub

    '別スレッドで実行する処理
    Private Sub SubThreadProcess()
        '処理1
        Threading.Thread.Sleep(1000)
        ReportProgress("処理1が終了しました。")     'この処理をメインスレッドで実行したい
        '処理2
        Threading.Thread.Sleep(1000)
        ReportProgress("処理2が終了しました。")     'この処理をメインスレッドで実行したい
        '処理3
        Threading.Thread.Sleep(1000)
        ReportProgress("処理3が終了しました。")     'この処理をメインスレッドで実行したい
    End Sub

    Private Sub ReportProgress(ByVal message As String)
        'SynchronizingObjectが設定されていればInvoke、そうでなければ普通に実行
        If Not _SynchronizingObject Is Nothing Then
            _SynchronizingObject.Invoke( _
                New OnProgressDelegate(AddressOf OnProgress), _
                New Object() {message})
        Else
            OnProgress(message)
        End If
    End Sub

    'OnProgressメソッド用のデリゲート
    Private Delegate Sub OnProgressDelegate(ByVal message As String)

    '処理の途中経過を報告するイベント
    Public Event Progress(ByVal sender As Object, ByVal e As ProgressEventArgs)

    'Progressイベントを発生させる
    Private Sub OnProgress(ByVal message As String)
        RaiseEvent Progress(Me, New ProgressEventArgs(message))
    End Sub

    'Progressイベントのイベント変数クラス
    Public Class ProgressEventArgs
        Inherits EventArgs

        Private _message As String

        Public ReadOnly Property Message() As String
            Get
                Return _message
            End Get
        End Property

        Public Sub New(ByVal message As String)
            _message = message
        End Sub

    End Class

End Class

'Class MyTreadClass
Public Class MyCallBacksKind
    Public Delegate Sub Progress(ByVal Message As String)
End Class
Public Property Reciever() As Object
Public Property ProgressHandler() As MyCallBacksKind.Progress
--------------------------------------------------------------
'Caller
objMyThread = New MyThreadClass
With objMyThread
    .Reciever = Me
    .ProgressHandler = New MyCallBacksKind.Progress(AddressOf MyThread_Progress)
    .StartThread()
End With
Private Sub MyThread_Progress(ByVal Message As String)
End Sub