【C#】別スレッドからのFormコントロール操作

'フォーム
Public Class Form1
    Inherits System.Windows.Forms.Form

#Region " Windows フォーム デザイナで生成されたコード "
    （省略）
#End Region

    Private WithEvents worker As New WorkerThreadClass

    Private Sub Button1_Click( _
        ByVal sender As System.Object, _
        ByVal e As System.EventArgs) _
    Handles Button1.Click
        worker.SynchronizingObject = Me
        worker.Start()
    End Sub

    Private Sub worker_Completed( _
        ByVal sender As Object, _
        ByVal e As WorkerThreadClass.CompletedEventArgs) _
    Handles worker.Completed
        MessageBox.Show(e.Message)
    End Sub
End Class

'ワーカスレッドクラス
Public Class WorkerThreadClass

    'スレッドオブジェクト
    Private _WorkerThread As Threading.Thread

    '同期用オブジェクト
    Private _SynchronizingObject As System.ComponentModel.ISynchronizeInvoke

    Public Property SynchronizingObject() As System.ComponentModel.ISynchronizeInvoke
        Get
            Return _SynchronizingObject
        End Get
        Set(ByVal Value As System.ComponentModel.ISynchronizeInvoke)
            _SynchronizingObject = Value
        End Set
    End Property

    'ワーカスレッドで重い処理を実行する
    Public Sub Start()
        _WorkerThread = _
            New Threading.Thread(New Threading.ThreadStart(AddressOf HeavyProcess))
        _WorkerThread.Start()
    End Sub

    'ワーカスレッドで実行する処理
    Private Sub HeavyProcess()
        Threading.Thread.Sleep(3000)
        OnCompleted(New CompletedEventArgs("重い処理は完了しました。"))
    End Sub

    '完了イベント
    Public Event Completed(ByVal sender As Object, ByVal e As CompletedEventArgs)

    '完了イベントを発生させる
    Private Sub OnCompleted(ByVal e As CompletedEventArgs)
        'SynchronizingObjectが設定されていて、InvokeRequiredがTrueならInvoke
        If ((Not CompletedEvent Is Nothing) AndAlso (Not _SynchronizingObject Is Nothing) AndAlso _SynchronizingObject.InvokeRequired) Then
            _SynchronizingObject.BeginInvoke(CompletedEvent, New Object() {Me, e})
        Else
            RaiseEvent Completed(Me, e)
        End If
    End Sub

    '完了イベント変数
    Public Class CompletedEventArgs
        Inherits EventArgs

        Private _message As String

        Public ReadOnly Property Message() As String
            Get
                Return _message
            End Get
        End Property

        Public Sub New(ByVal message As String)
            _message = message
        End Sub

    End Class

End Class