[解決]ASP.NETからのExcel作成でエラー

    Private Shared Sub MosaMosaAA()
        Dim xlApplication As Excel.Application

        Try
            xlApplication = New Excel.Application()
            Dim xlBooks As Excel.Workbooks

            Try
                xlBooks = xlApplication.Workbooks
                Dim xlBook As Excel.Workbook

                Try
                    xlBook = xlBooks.Add()
                    Dim xlSheet As Excel.Worksheet

                    Try
                        xlSheet = DirectCast(xlBook.ActiveSheet, Excel.Worksheet)
                        Dim xlCells As Excel.Range

                        Try
                            xlCells = xlSheet.Cells
                            Dim xlRange As Excel.Range

                            Try
                                xlRange = DirectCast(xlCells(1, 1), Excel.Range)
                                xlRange.Value2 = "テスト"
                            Finally
                                If Not xlRange Is Nothing Then
                                    System.Runtime.InteropServices.Marshal.ReleaseComObject(xlRange)
                                End If
                            End Try
                        Finally
                            If Not xlCells Is Nothing Then
                                System.Runtime.InteropServices.Marshal.ReleaseComObject(xlCells)
                            End If
                        End Try
                    Finally
                        If Not xlSheet Is Nothing Then
                            System.Runtime.InteropServices.Marshal.ReleaseComObject(xlSheet)
                        End If
                    End Try

                    xlBook.SaveAs("C:\MosaMosaAA.xls")
                Finally
                    If Not xlBook Is Nothing Then
                        Try
                            xlBook.Close()
                        Finally
                            System.Runtime.InteropServices.Marshal.ReleaseComObject(xlBook)
                        End Try
                    End If
                End Try
            Finally
                If Not xlBooks Is Nothing Then
                    System.Runtime.InteropServices.Marshal.ReleaseComObject(xlBooks)
                End If
            End Try
        Finally
            If Not xlApplication Is Nothing Then
                Try
                    xlApplication.Quit()
                Finally
                    System.Runtime.InteropServices.Marshal.ReleaseComObject(xlApplication)
                End Try
            End If
        End Try
    End Sub