動的に作成したプログラムを実行するようなことはできますか？

Imports System.CodeDom.Compiler
Imports System.Reflection
Imports System.Text

Module DynamicCompileAndRun
    Sub main()
        '動的に変更できるVBのプログラムソースコードを文字列化する
        Dim sbSource As New StringBuilder
        sbSource.Append("Imports Microsoft.VisualBasic" + vbCrLf)
        sbSource.Append("Public Class DynamicClass" + vbCrLf)
        sbSource.Append("  Sub DynamicMethod()" + vbCrLf)
        sbSource.Append("    MsgBox(""動的にコンパイルしたプログラムのMsgBox"")" + vbCrLf)
        sbSource.Append("  End Sub" + vbCrLf)
        sbSource.Append("End Class" + vbCrLf)
        Dim sSource = sbSource.ToString()

        'コンパイルを実行する
        Dim oCompilerParameters As New CompilerParameters
        oCompilerParameters.GenerateExecutable = False
        oCompilerParameters.GenerateInMemory = True
        Dim oVBCompiler As New VBCodeProvider
        Dim oCompilerResults As CompilerResults
        oCompilerResults = oVBCompiler.CompileAssemblyFromSource(oCompilerParameters, sSource)

        '動的コンパイルしたソースにエラーがあった場合、エラーを表示して、終了
        If oCompilerResults.Errors.Count >= 1 Then
            Debug.Print("動的に与えられたソースコードにコンパイルエラーがありました。")
            For Each oCompilerError As System.CodeDom.Compiler.CompilerError In oCompilerResults.Errors
                Debug.Print(oCompilerError.ToString())
            Next
            MsgBox("ソースコードにエラーがあります。イミディエイトウィンドウにエラーを表示しました。")
            Exit Sub
        End If

        'コンパイルしたアセンブリをインスタンス化して実行
        Dim oDynamicCompiledAssembly As Assembly = oCompilerResults.CompiledAssembly
        Dim oDynamicCompiledClassType As Type = oDynamicCompiledAssembly.GetType("DynamicClass")
        Dim oDynamicCompiledMethodInfo As MethodInfo = oDynamicCompiledClassType.GetMethod("DynamicMethod")
        Dim oDynamicCompiledInstance As Object = Activator.CreateInstance(oDynamicCompiledClassType)
        oDynamicCompiledMethodInfo.Invoke(oDynamicCompiledInstance, Nothing)
    End Sub
End Module