スレッドについて

Imports System.Text
Imports System.Threading

Module Module2

    Sub Main()
        Dim _name As String = Nothing
        Dim _priority As UInteger = 0
        Dim _argX As UInteger = 0
        Dim _thread As testThread2 = Nothing

        Dim _list As SortedList(Of UInteger, testThread2) = New SortedList(Of UInteger, testThread2)

        Do
            Console.Write("Thread Name (開始するには Enterキー)? ")
            _name = Console.ReadLine()
            If String.IsNullOrEmpty(_name) Then
                Exit Do
            End If
            Console.Write("Priority ? ")
            If Not UInteger.TryParse(Console.ReadLine(), _priority) Then
                Console.WriteLine("PriorityはUinteger型の範囲内で入力してください。")
                Continue Do
            End If
            If _list.ContainsKey(_priority) Then
                Console.WriteLine("入力されたPriorityは既に使用されています。")
                Continue Do
            End If
            Console.Write("ArgX(")
            Console.Write(UInteger.MinValue.ToString())
            Console.Write("〜")
            Console.Write(UInteger.MaxValue.ToString())
            Console.Write(") ? ")
            If Not UInteger.TryParse(Console.ReadLine(), _argX) Then
                Console.WriteLine("ArgXはUinteger型の範囲内で入力してください。")
                Continue Do
            End If
            _thread = New testThread2(_name, _priority, _argX)
            _list.Add(_thread.Priority, _thread)
        Loop

        Do
            Console.WriteLine("！！実行開始！！ ")

            For Each _targetKeyValuePair As KeyValuePair(Of UInteger, testThread2) In _list
                _targetKeyValuePair.Value.Start()
                _targetKeyValuePair.Value.join()
            Next

            Console.WriteLine("！！3000�_秒待機！！")
            Thread.Sleep(3000)
        Loop

    End Sub

End Module

Public Class testThread2

    Private _Name As String = Nothing
    Private _Priority As UInteger = 0
    Private _ArgX As UInteger = 0
    Private _InnerThread As Thread = Nothing
    Private _InnerTimer As Timer = Nothing
    Private _StartTime As DateTime = DateTime.MinValue

    Public Sub New(ByVal name As String, ByVal priority As UInteger, ByVal argX As UInteger)
        Me._Name = name
        Me._Priority = priority
        Me._ArgX = argX
    End Sub

    Public Sub Start()
        _StartTime = DateTime.Now
        Me._InnerThread = New Thread(New ThreadStart(AddressOf Method))
        Me._InnerThread.Start()
        Me._InnerTimer = New Timer(AddressOf SelfCheck, Nothing, 0, 25)
    End Sub

    Private Sub SelfCheck(ByVal state As Object)
        If Me._InnerTimer Is Nothing Then
            'タイマ停止済み
        ElseIf (DateTime.Now - Me._StartTime).Seconds > 1 Then
            Console.WriteLine(Me.Name & "はタイムアウトしました。")
            Me._InnerTimer.Dispose()
            Me._InnerTimer = Nothing
            Me._InnerThread.Abort()
        End If
    End Sub

    Public Sub Abort()
        If Me._InnerThread IsNot Nothing Then
            Me._InnerThread.Abort()
        End If
        If Me._InnerTimer IsNot Nothing Then
            Me._InnerTimer.Dispose()
        End If
    End Sub

    Public Sub join()
        Me._InnerThread.Join()
    End Sub

    Private Sub Method()
        Dim _result As StringBuilder = Nothing
        Dim _x As Double = 0.0R
        Dim _d As Integer = 0I
        Dim _q As Integer = 0I

        _result = New StringBuilder()

        _x = CType(Me.ArgX, Double)
        While (_x >= 4 And _x Mod 2 = 0)
            If _result.Length > 0 Then
                _result.Append(" * ")
            End If
            _result.Append("2")
            _x /= 2
            Thread.Sleep(25)
        End While
        _d = 3
        _q = CInt(_x / _d)
        While (_q >= _d)
            If (_x Mod _d = 0) Then
                If _result.Length > 0 Then
                    _result.Append(" * ")
                End If
                _result.Append(_d.ToString())
                _x = _q
            Else
                _d += 2
            End If
            _q = CInt(_x / _d)
            Thread.Sleep(25)
        End While
        If _result.Length > 0 Then
            _result.Append(" * ")
        End If
        _result.Append(_x)

        If Me._InnerTimer IsNot Nothing Then
            Me._InnerTimer.Dispose()
            Me._InnerTimer = Nothing
        End If

        Console.Write(Me.Name)
        Console.Write(" Priority : ")
        Console.Write(Me.Priority)
        Console.Write(" ArgX = ")
        Console.Write(Me.ArgX)
        Console.Write(" = ")
        Console.Write(_result.ToString())
        Console.WriteLine()

    End Sub

    Public ReadOnly Property Priority() As UInteger
        Get
            Return Me._Priority
        End Get
    End Property

    Public ReadOnly Property ArgX() As UInteger
        Get
            Return Me._ArgX
        End Get
    End Property

    Public ReadOnly Property Name() As String
        Get
            Return Me._Name
        End Get
    End Property

    Public ReadOnly Property IsAlive() As Boolean
        Get
            Return Me._InnerThread.IsAlive
        End Get
    End Property

    Public ReadOnly Property StartTime() As DateTime
        Get
            Return Me._StartTime
        End Get
    End Property

End Class