Flashで吹雪のごとき描画を実現するチューニング3策：速いFlash/ActionScriptチューニング入門（2）（4/4 ページ）

package  {
    
    import flash.display.*;
    import flash.events.Event;
    import flash.geom.Matrix;
    import flash.geom.Rectangle;
    
    /**
     * ベクタ画像の 0.2 〜 1.5 までのスケールにおける
     * 回転状態をプリレンダリングするクラスです
     */
    public class Prerendering extends MovieClip {
        
        /** プリレンダリング用 BitmapData 格納 Vector */
        private static var _bmdList:Array;
        
        /** x 方向の移動速度 */
        private var _x:Number;
        /** y 方向の移動速度 */
        private var _y:Number;
        
        /** rotation を override するため、別途変数を用意 */
        private var _rotation:Number;
        
        /** 表示用 Bitmap */
        private var _bmp:Bitmap;
        private var _scale:Number;
        
        /**
         * コンストラクタ
         */
        public function Graphic6() {
        
            // プリレンダリングが未完の場合は行う
            
            if ( !_bmdList ) {
            
                _bmdList = new Array();
                
                // GraphicBase は書き出したい元ベクタ MovieClip
                var mc:MovieClip = new GraphicBase();
                
                // MovieClipの矩形サイズを取得する
                var rect:Rectangle = mc.getBounds(this);
                var size:Number = Math.sqrt( rect.right * rect.right + rect.bottom * rect.bottom );
                
                // 0.2 〜 1.5までのスケール回転状態をプリレンダリングする
                for ( var s:uint = 2; s <= 15; s++ ){
                    
                    // スケールを計算
                    var scale:Number = s / 10;
                    
                    // レンダリング保持用 Vector を生成
                    _bmdList[s] = new Vector.<BitmapData>();
                    
                    // スケール s の回転状態を生成
                    for ( var i = 0; i < 360; i+=6 ) {
                            
                        // BitmapDataを生成
                        var bmd:BitmapData = new BitmapData( size * 2 * scale + 1, size * 2 * scale + 1, true, 0 );
 
                        // 変換Matrixを定義
                        var m:Matrix = new Matrix();
                        m.scale( scale, scale );
                        m.rotate( i * Math.PI / 180 );
                        m.tx = size * scale;
                        m.ty = size * scale;
 
                        // レンダリングと保持
                        bmd.draw( mc, m );
                        _bmdList[s][i] = bmd;
                    }
                }
            }
            
            // 以下インスタンスの処理
            
            _bmp = addChild( new Bitmap() ) as Bitmap;
            _scale = Math.max( 2, Math.round( Math.random() * 15 ) );
            rotation = super.rotation;
            
            // 初期位置を決定
            x = 30 + Math.random() * 700;
            y = -100 + 30 * Math.random();
            
            // 移動速度を決定
            _x = Math.max( 1, Math.round( 6 * Math.random() ) );
            _y = Math.max( 1, Math.round( 6 * Math.random() ) );
            
            // EnterFrame の処理を登録
            addEventListener(Event.ENTER_FRAME, _enterFrame);
            
        }
        
        /**
         * rotation.
         * 回転に応じた BitmapData を表示する処理に変えるため、override しています
         */
        override public function get rotation():Number{ return _rotation; };
        override public function set rotation( value:Number ):void{
            _rotation = Math.round( value % 360 )
            _bmp.bitmapData = _bmdList[_scale][_rotation / 6];
        }
        
        /**
         * EnterFrame Listener.
         * @param        e
         */
        public function _enterFrame(e:Event){
            x -= _x;
            y += _y;
            rotation += 6;
            if ( x < -80 || 480 < y ) {
                x = Math.random() * 700;
                y = -80;
            }
        }
        
    }
}