Flashで怒涛のごときイベント処理を捌きまくる3技

addEventListener( Event.ENTER_FRAME, trace );
addEventListener( Event.REMOVED_FROM_STAGE, _onRemoved );


// ステージから削除された際にremoveEventListenerする 
function _onRemoved(e:Event){
    removeEventListener( Event.ENTER_FRAME, trace );
    removeEventListener( Event.REMOVED_FROM_STAGE, _onRemoved );
}

// 各オブジェジェクトが個々にaddEventListenerするサンプルコード

import flash.display.MovieClip;
import flash.events.Event;

class ExMovieClip extends MovieClip {
    public function ExMovieClip():void {
        addEventListener( Event.ENTER_FRAME, _onEnterFrame );
    }
    private function _onEnterFrame(e:Event):void {
        x += 10;
    }
}

// イベントリスナを一括実行するサンプル

import flash.display.*;
import flash.events.Event;

class ExMovieClip extends MovieClip {
    
    // ENTER_FRAMEを共通して扱うためのSprite
    private static var _dispatcher:Sprite = new Sprite();
    // ENTER_FRAMEを共通して扱うためのSprite
    private static var _listeners:Vector.<Function> = new Vector.<Function>();
    
    public function ExMovieClip():void {
        // リスナ登録がない場合に登録
        if( !_dispatcher.hasEventListener(Event.ENTER_FRAME) ){
            _dispatcher.addEventListener(Event.ENTER_FRAME, function(e:Event):void{
                var len:uint = _listeners.length;
                for( var i:int = 0; i < len; i++ ){
                  _listeners[i](e);
              }
            })
        }
        addEventListener( Event.ENTER_FRAME, _onEnterFrame );
    }
    
    // addEventListenerをoverrideし、ENTER_FRAMEの場合は_listenersに登録
    override public function addEventListener( type:String, listener:Function, useCapture:Boolean = false,
                                               priority:int = 0, useWeakReference:Boolean = false ):void{
        if ( type == Event.ENTER_FRAME) {
            _listener.push(listener);
        }else {
            super.addEventListener(type, listener, useCapture, priority, useWeakReference);
        }
    }
    
    // removeEventListenerをoverrideし、ENTER_FRAMEの場合は_listenersから削除
    override public function removeEventListener( type:String, listener:Function,
                                                  useCapture:Boolean = false ):void{
        if ( type == Event.ENTER_FRAME) {
            for (var i:int = 0; i < _listener.length; i++) {
                if ( _listener[i] == listener ) _listener.splice(i, 1);
            }
        }else {
            super.removeEventListener(type, listener, useCapture);
        }
    }
    
    private function _onEnterFrame(e:Event):void {
        x += 10;
    }
}