第6回 VBScriptの配列を極める基礎解説 演習方式で身につけるチェック式WSH超入門(5/5 ページ)

» 2006年11月03日 00時00分 公開
前のページへ 1|2|3|4|5       

 VBScriptには、第4回で少し触れたように、配列を扱う関数がいくつか用意されている。例えば、“2006/10/19”という日付から、“Thu, 19 Oct 2006”という文字列を作成する方法を考えよう。

Option Explicit

Dim strMonthNames, strWeekNames, strDateName

'月の名前を格納する1次元配列
strMonthNames = _
Array("Jan", "Feb", "Mar", "Apr", _
"May", "Jun", "Jul", "Aug", _
"Sep", "Oct", "Nov", "Dec")

'曜日の名前を格納する1次元配列
strWeekNames = _
Array("Sun", "Mon", "Tue", "Wed", _
"Thu", "Fri", "Sat")

Dim dtmToday
dtmToday = Date

strDateName = _
strWeekNames(WeekDay(dtmToday) - 1) & _
", " & Day(dtmToday) & " " & _
strMonthNames(Month(dtmToday) - 1) & _
" " & Year(dtmToday)

MsgBox _
"月の一覧…" & Join(strMonthNames,"、") & _
"(計" & UBound(strMonthNames) + 1 & ")" & vbCrLf & _
"曜日の一覧…" & Join(strWeekNames,"、") & _
"(計" & UBound(strWeekNames) + 1 & ")" & vbCrLf & _
"本日:" & strDateName

 このスクリプトを実行すると、例えば次のようになる。

配列操作関数を用いた例
VBScriptの配列操作関数を使うと、配列の取り扱いが容易になる。

 日本語版Windowsを使っているとThuやOctなどという表記は、デフォルトでは使われない。そこで、これらの文字列を格納する配列を用意することになる。これまでのやり方だと、配列の各要素に値を格納していくことを繰り返さないといけないところだが、VBScriptにはArray関数という、引数に複数指定した値の集合を1次元配列として返す便利な関数があるのでそれを用いる。Array関数の戻り値は1次元配列だが、これを格納する変数strMonthNamesは通常の(配列ではない)変数である。このような配列を格納したバリアント型は、これまでに取り上げたバリアント型の要素を持つ配列とは異なるが、扱いは同じである。そのため、strMonthNames(Month(dtmToday) - 1)のように配列の1要素を取り出すことが可能である(1を減じているのは、配列のインデックスが0から始まることで生じるズレを補正するためである)。

 今回のように文字列を配列に格納する場合は、Split関数を用いることもできる。Split関数は、文字列を指定文字で分割した配列を返す。strMonthNamesに代入する部分は次のように書き換えられる。

'月の名前を格納する1次元配列
strMonthNames = _
Split("Jan,Feb,Mar,Apr,May,Jun,Jul,Aug,Sep,Oct,Nov,Dec", ",")

 このように、Split関数で月の名前の入った文字列を“,”(カンマ)で分割することで1次元配列を得ている。

 Join関数は、第1引数に指定した1次元配列の各要素を、第2引数で指定した文字(省略時は“,”(カンマ))で結合した文字列を返す関数である。またUBound関数は、第1引数に指定した配列で使用できるインデックスの最大値を返す。この場合、配列の要素数(サイズ)を取り出したいので、戻り値に+1をしていることに注意していただきたい。

 これらの配列処理関数を使うことで、指定文字列の中に含まれる特定文字(あるいは文字列)の数を数えることが簡単にできる。次の例題を考えてもらいたい。

CHECK!

マーカーで隠れたところを選択してチェックしてみよう。


Option Explicit
Dim strInput, strChr, intCount
strInput = InputBox("言葉を入力してください。")
strChr = "い" '数える文字
If InStr(strInput, strChr) >0 Then
'数える文字が1つ以上含まれていたら
    intCount = UBound(Split(strInput, strChr))
Else
    intCount = 0
End If
MsgBox "「" & strInput & "」の中に、「" & _
strChr & "」は" & intCount & "個あります。"

 このスクリプトにおいて、例えば「るいすしーてぃふぁにーていえんびじゅつかんまえ」と入力すると、次のような結果が得られる。

配列処理関数の利用例
配列処理関数を用いて、入力した文字列の中にある文字が何個含まれているかを数えている。

 この例では、Split関数の戻り値である1次元配列の、インデックスの最大値を求めることで、指定した文字の数を求めている。

 VBScriptの配列を扱う関数にはほかにも、変数が配列かどうかをブール値で返すIsArray関数、配列にフィルタをかけ、一致する要素が含まれた配列を返すFilter関数などがあるので、ヘルプを参照していただきたい。


 今回はVBScriptを使ううえで必須となる配列について取り上げ、それらを利用する方法を述べた。次回は、SubステートメントおよびFunctionステートメントを用いた関数の自作方法について述べる予定である。


「基礎解説 演習方式で身につけるチェック式WSH超入門」のインデックス

基礎解説 演習方式で身につけるチェック式WSH超入門

前のページへ 1|2|3|4|5       

Copyright© Digital Advantage Corp. All Rights Reserved.

RSSについて

アイティメディアIDについて

メールマガジン登録

@ITのメールマガジンは、 もちろん、すべて無料です。ぜひメールマガジンをご購読ください。