基礎解説
チェック式 WSH入門　第7回

2．Subプロシージャと引数（1）

Microsoft MVP
Visual Developer - Scripting
牟田口 大介
2006/12/07
Page1 Page2 Page3

引数を指定したSubプロシージャ

　先ほどの例では、Subプロシージャを呼び出すたびに毎回同じ動作をするが、呼び出し方によって異なった挙動をさせたいという場合もある。その際に用いるのが引数である。すでに第4回で関数と関数に与える引数について解説したが、それと基本は同じで、Subプロシージャの引数として与えた値（変数、リテラル、関数の戻り値など）に応じて異なった処理を行わせることができる。概念図を示すと次のようになる。

引数付きSubプロシージャ呼び出しの概念図
Subプロシージャを呼び出す際に引数（実引数）を渡すことで、Subプロシージャ側の仮引数に実引数の値が代入され使用される。

　次の例は、前回登場した、指定した日付の英語日付表記を得るものであるが、表示部分をSubプロシージャ化している。

Option Explicit

ShowDateNotation #2016/6/29#
ShowDateNotation Date

'*********************************************************
 '用途: 与えられた日付から英語日付表記を得て表示する。
 '受け取る値: dtmDate: 日付(Date)
 '戻り値: なし
 '*********************************************************
 Sub ShowDateNotation(dtmDate)
        Dim strMonthNames, strWeekNames, strDateName

        '月の名前を格納する1次元配列
         strMonthNames = _
        Array("Jan", "Feb", "Mar", "Apr", _
        "May", "Jun", "Jul", "Aug", _
        "Sep", "Oct", "Nov", "Dec")

        '曜日の名前を格納する1次元配列
         strWeekNames = _
        Array("Sun", "Mon", "Tue", "Wed", _
        "Thu", "Fri", "Sat")

        strDateName = _
        strWeekNames(WeekDay(dtmDate) - 1) & _
        ", " & Day(dtmDate) & " " & _
        strMonthNames(Month(dtmDate) - 1) & _
        " " & Year(dtmDate)

        MsgBox CStr(dtmDate) & vbCrLf & strDateName
End Sub

　このスクリプトを実行すると、例えば次のように2回メッセージ・ボックスが表示される。

SubプロシージャShowDateNotationを実行した例
与えられた日付のデータから、英語日付表記を取得し、メッセージ・ボックスに表示している。

　この例では、SubプロシージャShowDateNotationに#2016/6/29#という日付リテラル、Date関数の戻り値（今日の日付）をそれぞれ引数として渡している。このとき、渡す引数を実引数ともいう。SubプロシージャShowDateNotationは、渡された引数から英語日付表示を生成し、それを表示する。Sub ShowDateNotation(dtmDate)のdtmDateを仮引数といい、呼び出し元から与えられた実引数の値が仮引数に代入される。すなわち、#2016/6/29#という日付リテラルおよびDate関数の戻り値がそれぞれ仮引数に渡されてSubプロシージャ内で参照されるというわけである。

　なお、Subプロシージャの呼び出しにCallステートメントを用いることができる。

ShowDateNotation #2016/6/29#
ShowDateNotation Date

の代わりに、

Call ShowDateNotation (#2016/6/29#)
Call ShowDateNotation (Date)

と記述することでも同じ結果が得られる。Callステートメントを使うときは、引数に ( ) を付ける必要があるので注意しよう。

参照渡しと値渡し

　プロシージャに引数を渡す場合、「参照渡し（call by reference）」と「値渡し（call by value）」という2つの方法がある。

　VBScriptにおける引数は、デフォルトでは参照渡しであり、変数の参照を引数として渡す。これはどういうことかというと、プロシージャ内で仮引数の値を変更した場合、実引数として渡した変数の値も変更されるということである。次の例を見てもらいたい。

Option Explicit
Dim lngInitialNumber
lngInitialNumber = 5

Call ShowSquare(lngInitialNumber)
MsgBox "lngInitialNumber: " & lngInitialNumber

Sub ShowSquare(lngNumber)
        lngNumber = lngNumber * lngNumber
        MsgBox "自乗の値:" & lngNumber
End Sub

　これは、与えられた数値を自乗し、その結果を表示するという単純なサンプルだが、SubプロシージャShowSquare内で仮引数lngNumberにそのまま自乗の値を代入している。実引数は参照渡しされているので、lngInitialNumberの値は最初の5とは異なり、25となる。

　参照渡しに対し、値のコピーを引数に渡す、値渡しをさせるにはSubプロシージャを次のように記述する。

Sub ShowSquare(ByVal lngNumber)
        lngNumber = lngNumber * lngNumber
        MsgBox "自乗の値:" & lngNumber
End Sub

　このようにByValキーワードを用いることで実引数は値渡しされるので、lngInitialNumberの値は元の値から変化せず5となる。

　なお、VBScriptにおいては、ByVal（値渡しさせるためのキーワード）もしくはByRef（参照渡しさせるためのキーワード）を記述しない場合はByRefが省略されていると解釈される。

　また、後述するFunctionプロシージャでも参照渡しと値渡しの引数をそれぞれ渡すことができる。


　INDEX
　 ［基礎解説］チェック式 WSH入門
　 第7回　Subプロシージャでユーザー独自の処理を定義する
　   1．Subプロシージャとは
  2．Subプロシージャと引数（1）
　   3．Subプロシージャと引数（2）
　
　基礎解説

TechTargetジャパン

Windows Server Insider フォーラム 新着記事

＠ITメールマガジン　新着情報やスタッフのコラムがメールで届きます（無料）

RSSフィード

＠IT 新着記事

キャリアアップ

- PR -
＠IT Sepcial
→ ＠IT Special ヘ

イベントカレンダー

PickUpイベント

- PR -
もっと見る
- PR -

お勧め求人情報

ホワイトペーパー（TechTargetジャパン）

＠IT Sepcial
→ ＠IT Special ヘ
ソリューションFLASH