【2/17】今年は「濃厚」技術トーク！＠ITメールセミナー スラッシュドット    はてなブックマーク  Yahoo!ブックマークに登録  印刷
　 　
基礎解説
チェック式 WSH入門　第11回

4．COMオブジェクトの操作（2）

Microsoft MVP
Windows Server - Admin Frameworks
牟田口 大介
2007/07/26

ConnectObjectメソッドとDisconnectObjectメソッド

　次にConnectObjectメソッドおよびDisconnectObjectメソッドについて説明する。ConnectObjectメソッドもCreateObjectメソッドの第2引数を指定したときと同様、オブジェクトに接続し、そのイベントを捕捉するために用いるが、CreateObjectメソッドで直接生成できないオブジェクト（CreateObjectメソッドで生成したオブジェクトのプロパティやメソッドからアクセスできるようなもの）に対しても用いることができる。

　ここではMicrosoft OfficeのWordアプリケーションの制御をするためのWordオブジェクト（ProgIDはWord.Application）を作成し、そのオブジェクトのプロパティおよびメソッドからアクセス可能なDocumentオブジェクトを取得したあと、そのオブジェクトにConnectObjectメソッドを用いて接続してみる。なおこのスクリプトを実行するにはWord 2000以降がインストールされている必要がある。

※ファイル：monitor_word.vbs

Option Explicit

'Wordオブジェクトを作成
Dim objWord
Set objWord = WScript.CreateObject("Word.Application")

'ウィンドウを可視状態にする
objWord.Visible = True

'新規ドキュメントを追加する。同時にAddメソッドが返すDocumentオブジェクトを変数に代入
Dim objDocument
Set objDocument = objWord.Documents.Add()

'objDocumentオブジェクト変数に接続。イベントのプリフィックスを指定
WScript.ConnectObject objDocument, "Document_"

'空ループを回し、イベントの発生を監視する
Do
    WScript.Sleep 100
Loop

'DocumentオブジェクトのCloseイベント
Sub Document_Close()
    MsgBox "Word ドキュメントが閉じられました。"

    'オブジェクトの破棄
    Set objWord = Nothing
    Set objDocument = Nothing

    'スクリプトの終了
    WScript.Quit()
End Sub

　このスクリプトを実行するとWordが起動し、ドキュメントを新規作成した後、Do〜Loop無限ループによりイベント発生まで待機する。ユーザーによってWordのウィンドウが閉じられると、Closeイベントが発生し、スクリプトの終了処理に入る。

　このように、ConnectObjectメソッドを使えば、CreateObjectメソッドでは直接生成できないオブジェクトのイベントを監視することが可能である。なお、DisconnectObjectメソッドは引数に監視中のオブジェクト変数を指定することでイベント監視を解除することができる（ただし、イベント発生中に実行するとエラーになるので注意）。

GetObjectメソッド

　最後にGetObjectメソッドについて説明する。GetObjectメソッドはCreateObjectメソッドとは異なり、すでに存在し動作しているオブジェクトを取得してその機能を呼び出すために用いる。GetObjectメソッドの引数にはファイル・パスを指定したり、モニカと呼ばれる実行中のオブジェクトの種類を示す文字列を指定したりすることが可能だ。ここではWMI（Windows Management Instrumentation）のオブジェクトを示すモニカを指定することでWMIサービス・オブジェクトを取得し、そのメソッドを実行することでWin32_Processorクラスのコレクションを得て、システムに搭載されているCPUの情報を取得する例をご覧にいれよう。なおここではGetObjectメソッドの使い方を説明するにとどめ、WMIについての詳説は行わない。WMIがどういうもので、どういう機能・クラスを呼び出し可能であるかについては、WMI スクリプト入門（マイクロソフトMSDNサイト）やWindows TIPS「WMIを使うスクリプトを簡単に作成する」などを参考にされたい。

※ファイル：list_cpu.vbs

Option Explicit

'コンピュータ名を指定（ここではローカル・コンピュータ）
Dim strComputer
strComputer = "."

'WMIのサービス・オブジェクトを取得
Dim objWMIService
Set objWMIService = GetObject("winmgmts:" &_
    "{impersonationLevel=impersonate}!\\" & _
    strComputer & "\root\cimv2")

'Win32_Win32_Processorクラスのオブジェクトのコレクションを取得。
Dim objProcessors
Set objProcessors = objWMIService.ExecQuery _
    ("Select * From Win32_Processor")

'CPU情報を格納する文字列変数宣言。
Dim strCPUInfo
strCPUInfo = ""

'Win32_Processorコレクションに含まれる各要素を列挙。
Dim objProcessor
For Each objProcessor In objProcessors
    strCPUInfo = strCPUInfo & _
        "CPU名: " & objProcessor.Name & vbCrLf & _
        "CPUの種類: " & objProcessor.Description & vbCrLf & _
        "クロック数: " & objProcessor.CurrentClockSpeed & vbCrLf & _
        vbCrLf
Next

MsgBox strCPUInfo

'オブジェクトの破棄
Set objWMIService = Nothing
Set objProcessor = Nothing
Set objProcessors = Nothing

　このスクリプトを実行すると、例えば次のようなメッセージ・ボックスが表示される。

WMIサービス・オブジェクトからWin32_Processorオブジェクトを参照する
このように、CPU名、種類、クロック数（MHz単位）が取得できることが分かる。

　このスクリプトにおいて、GetObjectメソッドを用いてWMIのサービス・オブジェクトを取得しているのがポイントである。WMIのサービス・オブジェクトはExecQueryメソッドを持ち、その引数にクラス名（ここではWin32_Processor）を取得するためのクエリー（問い合わせ文字列）を指定し、オブジェクトのコレクションを得ている。あとは、コレクションに含まれる各オブジェクトをFor〜Each〜Nextステートメントを用いて列挙し、そのプロパティを参照している。

　なお、GetObjectメソッドもCreateObjectメソッド同様にProgIDやイベントに接続するためのプリフィックスを指定することもできる。また、VBScriptにもGetObject関数が存在するが、プリフィックスを指定できるか否かの違いがあるだけで、基本的には同様の動作をする。

■

　今回は前回に引き続きWScriptオブジェクトに含まれるプロパティ／メソッドを紹介した。次回からはCreateObjectメソッドを用いて呼び出すWSHの内部オブジェクトについて個別に解説していく予定である。


　INDEX
　 ［基礎解説］チェック式 WSH入門
　 第11回　WScriptオブジェクトを利用する（2）
　   1．標準入出力と標準エラー出力
　   2．スクリプトの実行制御
　   3．COMオブジェクトの操作（1）
  4．COMオブジェクトの操作（2）
　    コラム：タイプ・ライブラリについて

　基礎解説

ホワイトペーパー（TechTargetジャパン）

Windows Server Insider フォーラム 新着記事

＠ITメールマガジン　新着情報やスタッフのコラムがメールで届きます（無料）

RSSフィード

＠IT 新着記事

スキルアップ／キャリアアップ（JOB@IT）

- PR -
＠IT Special -PR-
操作もマニュアルも分かりやすい！
ユーザー視点で開発されたPC管理ツール
New！
【CTC事例】約30の基幹システムを統合！
膨大なバッチジョブを制御した方法は？
「どこでもオフィス」で業務効率アップ！
PHP研究所モバイルシンクライアント事例
コスト削減・信頼性向上をまとめて満たす
“高信頼Linux”を構築する方法とは？
世界に通用するストレージの作り方とは？
製品に込めた思いを富士通の開発者に聞く
急速に広がるHyper-Vでのサーバ仮想化
そのベストプラクティスをデルが解説
＠IT「Windows 7」 特設サイトオープン！
最新情報・移行ノウハウを公開しています

→＠IT Special ヘ

- PR -

お勧め求人情報

キャリアアップ　〜JOB＠IT
＠IT Special -PR-
◆ 　 企業の仮想化に足りない“発想”とは？
仮想化運用管理のキモは意外なところに！
New！
◆ 　 操作もマニュアルも分かりやすい！
ユーザー視点で開発されたPC管理ツール
New！
◆ 　 仮想化すればコストは削減できるか？
仮想化に必要な「3つの視点」を解説する

◆ 　 セキュリティを知り尽くす上野氏が登壇！
＠ITメールソリューションLive! in Tokyo
◆ 　 運用管理の課題を“2つの観点”から分析
ユーザー満足度の高い「仮想環境」とは？
◆ 　 世界に通用するストレージの作り方とは？
製品に込めた思いを富士通の開発者に聞く

◆ 　 OSSで手間も時間も、障害も減った――
「マピオンの事例」オープンソース活用法
◆ 　 「ノートPCの持ち出し禁止」で大丈夫？
情報漏えいを防ぐ管理手法とインフラは？
◆ 　 1日の処理を1秒に――MySQLの達人が語る
「コスト削減」できるチューニング

◆ 　 ドキュメント作成を自動化して、SEの作業
効率を大幅アップ！ Visio 2007の魅力
◆ 　 急速に広がるHyper-Vでのサーバ仮想化
そのベストプラクティスをデルが解説
◆ 　 ＠IT主催セミナーで語られた、「担当者に
求められるセキュリティ対策」をレポート

◆ 　 ＠IT「Windows 7」 特設サイトオープン！
最新情報・移行ノウハウを公開しています

→＠IT Special ヘ