連載
» 2007年01月12日 00時00分 公開

基礎解説 演習方式で身につけるチェック式WSH超入門:第8回 Functionプロシージャでユーザー独自の関数を定義する (1/3)

Functionプロシージャでユーザー独自の関数を定義してみよう。さまざまなループ・ステートメント構文や再帰呼び出しについても学ぶ。

[牟田口大介(Microsoft MVP Visual Developer - Scripting),著]
基礎解説 演習方式で身につけるチェック式WSH超入門
Windows Server Insider


「基礎解説 演習方式で身につけるチェック式WSH超入門」のインデックス

連載目次

 前回は、ユーザー独自の処理を行うSubプロシージャについて解説した。これは一連の手続きをまとめて名前を付けたものであり、同じ処理を何度も繰り返す場合に簡単に呼び出すことができる。また引数を使うと、同じプロシージャでも、呼び出すたびに異なる処理を行わせることができる。今回はSubプロシージャと対をなす、Functionプロシージャについて解説する。

Functionプロシージャとは

 Functionプロシージャとは、Functionステートメントを用いて定義されるユーザー独自の関数のことである(“Function”は「関数」を意味する英単語である)。Subプロシージャが呼び出し元に値を返さなかったのに対し、Functionプロシージャは呼び出し元に値を返すのが特徴である。つまり、VBScriptの関数と同様、戻り値を参照したり、式の「=」記号の右側に記述することで、変数に代入したりできるということである。概念図を示すと次のようになる。

Functionプロシージャの概念図
Functionプロシージャとは、一連の手続きを経た後、呼び出し元に値を返すプロシージャである。

 Functionプロシージャの実際例を見てみよう。これは、Functionプロシージャでおみくじを引き、その結果を返すものである。

Option Explicit
Randomize
Dim strMessage
strMessage = "あなたの今日の運勢は:" & GetOmikuji() & vbCrLf & _
    "明日の運勢は:" & GetOmikuji()
MsgBox strMessage

'*********************************************************
'用途: おみくじの入った文字列を返す
'受け取る値: なし
'戻り値: おみくじの文字列(String)
'*********************************************************
Function GetOmikuji()
    Dim strOmikujis, strOmikuji
    'おみくじの一覧を格納した配列
    strOmikujis = Array("大吉", "中吉", "小吉", "吉", "末吉", "凶", "大凶")
    'おみくじを引く(ランダムに1つ取り出す)
    strOmikuji = strOmikujis(Int((UBound(strOmikujis) + 1) * Rnd))
    '結果を戻り値として返す
    GetOmikuji = strOmikuji
End Function

 このスクリプトを実行すると、例えば次のようなメッセージ・ボックスが表示される。

FunctionプロシージャGetOmikujiの実行例
おみくじの結果を返すFunctionプロシージャGetOmikujiを呼び出し、その結果を表示している。

 この例ではGetOmikujiという名前のFunctionプロシージャを定義し、それを1つのステートメントの中で2回呼び出して、戻り値を参照している。

 Functionプロシージャは、以下のように記述する。

Function <Functionプロシージャ名> ()
        〜(Functionプロシージャの内容)〜
        <Functionプロシージャ名"> =
End Function

 FunctionプロシージャGetOmikuji内では、おみくじの結果が含まれた配列を作成し、そこからランダムなインデックスを参照して、ランダムに1つのおみくじを取り出している。結果をFunctionプロシージャ名と同じGetOmikujiに代入することにより、この値が戻り値となって、呼び出し元に値を返す。その後はstrMessage変数にこれらの値を結合したものが代入され、MsgBox関数を使って表示している。

 このように、Functionステートメントを用いて独自の関数を作成し、何度も呼び出すことができる。

 なお、Functionプロシージャを呼ぶ場合は()を付けるのが基本だが、この例のように引数がない場合は省略することもできる。


       1|2|3 次のページへ

Copyright© Digital Advantage Corp. All Rights Reserved.

RSSについて

アイティメディアIDについて

メールマガジン登録

@ITのメールマガジンは、 もちろん、すべて無料です。ぜひメールマガジンをご購読ください。