第11回 WScriptオブジェクトを利用する(2)基礎解説 演習方式で身につけるチェック式WSH超入門(4/5 ページ)

» 2007年07月26日 00時00分 公開

ConnectObjectメソッドとDisconnectObjectメソッド

 次にConnectObjectメソッドおよびDisconnectObjectメソッドについて説明する。ConnectObjectメソッドもCreateObjectメソッドの第2引数を指定したときと同様、オブジェクトに接続し、そのイベントを捕捉するために用いるが、CreateObjectメソッドで直接生成できないオブジェクト(CreateObjectメソッドで生成したオブジェクトのプロパティやメソッドからアクセスできるようなもの)に対しても用いることができる。

 ここではMicrosoft OfficeのWordアプリケーションの制御をするためのWordオブジェクト(ProgIDはWord.Application)を作成し、そのオブジェクトのプロパティおよびメソッドからアクセス可能なDocumentオブジェクトを取得したあと、そのオブジェクトにConnectObjectメソッドを用いて接続してみる。なおこのスクリプトを実行するにはWord 2000以降がインストールされている必要がある。

※ファイル:monitor_word.vbs

Option Explicit

'Wordオブジェクトを作成
Dim objWord
Set objWord = WScript.CreateObject("Word.Application")

'ウィンドウを可視状態にする
objWord.Visible = True

'新規ドキュメントを追加する。同時にAddメソッドが返すDocumentオブジェクトを変数に代入
Dim objDocument
Set objDocument = objWord.Documents.Add()

'objDocumentオブジェクト変数に接続。イベントのプリフィックスを指定
WScript.ConnectObject objDocument, "Document_"

'空ループを回し、イベントの発生を監視する
Do
    WScript.Sleep 100
Loop

'DocumentオブジェクトのCloseイベント
Sub Document_Close()
    MsgBox "Word ドキュメントが閉じられました。"

    'オブジェクトの破棄
    Set objWord = Nothing
    Set objDocument = Nothing

    'スクリプトの終了
    WScript.Quit()
End Sub

 このスクリプトを実行するとWordが起動し、ドキュメントを新規作成した後、Do〜Loop無限ループによりイベント発生まで待機する。ユーザーによってWordのウィンドウが閉じられると、Closeイベントが発生し、スクリプトの終了処理に入る。

 このように、ConnectObjectメソッドを使えば、CreateObjectメソッドでは直接生成できないオブジェクトのイベントを監視することが可能である。なお、DisconnectObjectメソッドは引数に監視中のオブジェクト変数を指定することでイベント監視を解除することができる(ただし、イベント発生中に実行するとエラーになるので注意)。

GetObjectメソッド

 最後にGetObjectメソッドについて説明する。GetObjectメソッドはCreateObjectメソッドとは異なり、すでに存在し動作しているオブジェクトを取得してその機能を呼び出すために用いる。GetObjectメソッドの引数にはファイル・パスを指定したり、モニカと呼ばれる実行中のオブジェクトの種類を示す文字列を指定したりすることが可能だ。ここではWMI(Windows Management Instrumentation)のオブジェクトを示すモニカを指定することでWMIサービス・オブジェクトを取得し、そのメソッドを実行することでWin32_Processorクラスのコレクションを得て、システムに搭載されているCPUの情報を取得する例をご覧にいれよう。なおここではGetObjectメソッドの使い方を説明するにとどめ、WMIについての詳説は行わない。WMIがどういうもので、どういう機能・クラスを呼び出し可能であるかについては、WMI スクリプト入門(マイクロソフトMSDNサイト)やWindows TIPS「WMIを使うスクリプトを簡単に作成する」などを参考にされたい。

※ファイル:list_cpu.vbs

Option Explicit

'コンピュータ名を指定(ここではローカル・コンピュータ)
Dim strComputer
strComputer = "."

'WMIのサービス・オブジェクトを取得
Dim objWMIService
Set objWMIService = GetObject("winmgmts:" &_
    "{impersonationLevel=impersonate}!\\" & _
    strComputer & "\root\cimv2")

'Win32_Win32_Processorクラスのオブジェクトのコレクションを取得。
Dim objProcessors
Set objProcessors = objWMIService.ExecQuery _
    ("Select * From Win32_Processor")

'CPU情報を格納する文字列変数宣言。
Dim strCPUInfo
strCPUInfo = ""

'Win32_Processorコレクションに含まれる各要素を列挙。
Dim objProcessor
For Each objProcessor In objProcessors
    strCPUInfo = strCPUInfo & _
        "CPU名: " & objProcessor.Name & vbCrLf & _
        "CPUの種類: " & objProcessor.Description & vbCrLf & _
        "クロック数: " & objProcessor.CurrentClockSpeed & vbCrLf & _
        vbCrLf
Next

MsgBox strCPUInfo

'オブジェクトの破棄
Set objWMIService = Nothing
Set objProcessor = Nothing
Set objProcessors = Nothing

 このスクリプトを実行すると、例えば次のようなメッセージ・ボックスが表示される。

WMIサービス・オブジェクトからWin32_Processorオブジェクトを参照する
このように、CPU名、種類、クロック数(MHz単位)が取得できることが分かる。

 このスクリプトにおいて、GetObjectメソッドを用いてWMIのサービス・オブジェクトを取得しているのがポイントである。WMIのサービス・オブジェクトはExecQueryメソッドを持ち、その引数にクラス名(ここではWin32_Processor)を取得するためのクエリー(問い合わせ文字列)を指定し、オブジェクトのコレクションを得ている。あとは、コレクションに含まれる各オブジェクトをFor〜Each〜Nextステートメントを用いて列挙し、そのプロパティを参照している。

 なお、GetObjectメソッドもCreateObjectメソッド同様にProgIDやイベントに接続するためのプリフィックスを指定することもできる。また、VBScriptにもGetObject関数が存在するが、プリフィックスを指定できるか否かの違いがあるだけで、基本的には同様の動作をする。


 今回は前回に引き続きWScriptオブジェクトに含まれるプロパティ/メソッドを紹介した。次回からはCreateObjectメソッドを用いて呼び出すWSHの内部オブジェクトについて個別に解説していく予定である。

Copyright© Digital Advantage Corp. All Rights Reserved.

RSSについて

アイティメディアIDについて

メールマガジン登録

@ITのメールマガジンは、 もちろん、すべて無料です。ぜひメールマガジンをご購読ください。