第18回　FileSystemObjectオブジェクトを利用する（3）：基礎解説 演習方式で身につけるチェック式WSH超入門（1/2 ページ）

※ファイル：dir.vbs

Option Explicit

'FileSystemObjectオブジェクト変数の宣言とインスタンスの代入
Dim objFSO
Set objFSO = WScript.CreateObject("Scripting.FileSystemObject")

'出力メッセージを保持する変数宣言
Dim strMessage
strMessage = ""

'親フォルダのパスと親フォルダのFolderオブジェクトを格納する変数宣言
Dim strParentFolder, objParentFolder

'スクリプトが存在するフォルダの親フォルダのパスを取得
strParentFolder = objFSO.GetParentFolderName(WScript.ScriptFullName)

'親フォルダを表すFolderオブジェクトを取得して代入
Set objParentFolder = objFSO.GetFolder(strParentFolder)

'1つのサブフォルダおよびサブフォルダのセットを表すオブジェクト変数を宣言
Dim objSubFolder, objSubFolders

'FolderオブジェクトのSubFoldersプロパティを参照し、Foldersコレクションを得る
Set objSubFolders = objParentFolder.SubFolders

'サブフォルダのFolderオブジェクトを列挙
For Each objSubFolder In objSubFolders
       'サブフォルダのフォルダ名を取得
       strMessage = strMessage & objSubFolder.Name & vbCrLf
Next
Set objSubFolder = Nothing
Set objSubFolders = Nothing

'1つのファイルおよびファイルのセットを表すオブジェクト変数を宣言
Dim objFile, objFiles

'FolderオブジェクトのFilesプロパティを参照し、Filesコレクションを得る
Set objFiles = objParentFolder.Files

'フォルダに存在するファイルのFileオブジェクトを列挙
For Each objFile In objParentFolder.Files
       'ファイル名を取得
       strMessage = strMessage & objFile.Name & vbCrLf
Next
Set objFile = Nothing
Set objFiles = Nothing

'サブフォルダとファイル名の一覧を表示
MsgBox strMessage

Set objFSO = Nothing

マーカーで隠れたところを選択してチェックしてみよう。

※ファイル：recursiveDir.vbs

Option Explicit

Dim objFSO
Set objFSO = WScript.CreateObject("Scripting.FileSystemObject")

Dim strMessage
strMessage = ""

Dim strParentFolder, objParentFolder
strParentFolder = objFSO.GetParentFolderName(WScript.ScriptFullName)
Set objParentFolder = objFSO.GetFolder(strParentFolder)

'親フォルダを表すFolderオブジェクトをプロシージャSearchFolderに渡す
Call SearchFolder(objParentFolder)

'Folderオブジェクトを引数に取り、そのフォルダに含まれるサブフォルダ、ファイルを
'列挙するSubプロシージャ。引数にはFolderオブジェクトを取る
Sub SearchFolder(objFolder)
       '引数に与えられたフォルダのパスを取得する
       strMessage = strMessage & objFolder.Path& vbCrLf
      
       '1つのファイルおよびファイルのセットを表すオブジェクト変数を宣言
       Dim objFile, objFiles
      
       'FolderオブジェクトのFilesプロパティを参照し、Filesコレクションを得る
       Set objFiles = objFolder.Files
      
       'フォルダに存在するファイルのFileオブジェクトを列挙
       For Each objFile In objFiles
              'ファイルパスを取得
              strMessage = strMessage & objFile.Path & vbCrLf
       Next

       Set objFile = Nothing
       Set objFiles = Nothing

       '1つのサブフォルダおよびサブフォルダのセットを表すオブジェクト変数を宣言
       Dim objSubFolder, objSubFolders
      
       'FolderオブジェクトのSubFoldersプロパティを参照し、Foldersコレクションを得る
       Set objSubFolders = objFolder.SubFolders

       'サブフォルダに対して、SubプロシージャSearchFolderを再帰呼び出しする
      For Each objSubFolder In objSubFolders
              Call SearchFolder(objSubFolder)
       Next
       Set objSubFolder = Nothing
       Set objSubFolders = Nothing
End Sub

MsgBox strMessage

Set objFSO = Nothing