選択した画像をトリミングして保存させるには：2カ月で160本作った還暦開発者が送る10のアプリ開発ノウハウ（9）（4/4 ページ）

    Private Async Sub Button1_Click(sender As Object, e As RoutedEventArgs) Handles Button1.Click
        Try
            Dim myWriteableBitmap = New WriteableBitmap(CInt(Rectangle1.Width), CInt(Rectangle1.Height))
　　　　　　　　　‘　このプログラムの肝。矩形で選択された部分を切り出す処理だ。
            Dim myCrop = Await myWriteableBitmap.FromStream(Await myFile.OpenReadAsync)
            mySelectedImage = myCrop.Crop(CInt(Rectangle1.Margin.Left), CInt(Rectangle1.Margin.Top), CInt(Rectangle1.Width), CInt(Rectangle1.Height))
            resultImage.Width = Rectangle1.Width
            resultImage.Height = Rectangle1.Height
            resultImage.Source = mySelectedImage
            mySelectedImage.Invalidate()
            saveButton.Visibility = Windows.UI.Xaml.Visibility.Visible
            saveButton.IsEnabled = True
        Catch
            ErrorShow()
        End Try
    End Sub

WriteableBitmap.Crop(x As Integer,y As Integer,width As Integer,height As Integer)

    Private Async Sub saveButton_Click(sender As Object, e As RoutedEventArgs) Handles saveButton.Click
        Dim myFolder As StorageFolder = Windows.Storage.KnownFolders.PicturesLibrary
        Dim SubFolder = Await myFolder.CreateFolderAsync("TrimingImage", CreationCollisionOption.OpenIfExists)
        Dim mySaveFile As StorageFile = Await SubFolder.CreateFileAsync(DateTime.Now.ToString("yyyyMMddHHmmss") & ".png")
        Dim myID As Guid = Windows.Graphics.Imaging.BitmapEncoder.PngEncoderId
        Await WriteableBitmapSaveExtensions.SaveToFile(mySelectedImage, mySaveFile, myID)
        Dim saveMessage As New MessageDialog("ピクチャフォルダー内のTrimingImageフォルダに保存しました。")
        Await saveMessage.ShowAsync
        GridView1.Items.Clear()
        saveButton.Visibility = Windows.UI.Xaml.Visibility.Collapsed
        Await AddPhoto()
    End Sub

WriteableBitmapSaveExtensions.SaveToFile(writeableBitmap as Windows.UI.Xaml.Media.Imageing.WriteableBitmap,output as Windows.Storages.StorageFile,encodeId as System.GUID)

    Private Async Function AddPhoto() As Task
        Dim myFolder As StorageFolder = Windows.Storage.KnownFolders.PicturesLibrary
        Dim mySubFolder = Await myFolder.CreateFolderAsync("TrimingImage", CreationCollisionOption.OpenIfExists)
        myPictureFiles = Await mySubFolder.GetFilesAsync()
        If myPictureFiles.Count > 0 Then
            deleteButton.IsEnabled = True
            allDeleteButton.IsEnabled = True
        Else
            deleteButton.IsEnabled = False
            allDeleteButton.IsEnabled = False
        End If
        For Each myPhotoFile In myPictureFiles
            Dim bmp As New BitmapImage
            bmp.SetSource(Await myPhotoFile.OpenSequentialReadAsync)
            Dim myImage As New Image
            myImage.Stretch = Stretch.Uniform
            myImage.Width = 80
            myImage.Height = 60
            myImage.Source = bmp
            Dim myFileName As New TextBlock
            myFileName.Text = myPhotoFile.Name
            FileName = myPhotoFile.Path
            myFileName.FontSize = 10
            myFileName.HorizontalAlignment = Windows.UI.Xaml.HorizontalAlignment.Center
            Dim myStackPanel As New StackPanel
            myStackPanel.Margin = New Thickness(3)
            myStackPanel.Children.Add(myImage)
            myStackPanel.Children.Add(myFileName)
            GridView1.Items.Add(myStackPanel)
        Next
        Index = myPictureFiles.Count
        If Index <= 0 Then
　　　　　　　　　Button1.IsEnabled = False
            Exit Function
        Else
            Dim message As New MessageDialog("一番新しいファイルが選択されます。")
            Await message.ShowAsync
            GridView1.Focus(Windows.UI.Xaml.FocusState.Keyboard)
            GridView1.SelectedIndex = Index - 1
            GridView1.ScrollIntoView(GridView1.SelectedItem)
        End If
    End Function

    Private Async Sub GridView1_SelectionChanged(sender As Object, e As SelectionChangedEventArgs) Handles GridView1.SelectionChanged
        flag = True
        Dim myIndex As Integer = GridView1.SelectedIndex
        If myIndex < 0 Then
            Exit Sub
        Else
            Dim myFolder As StorageFolder = Windows.Storage.KnownFolders.PicturesLibrary
            Dim mySubFolder = Await myFolder.CreateFolderAsync("TrimingImage", CreationCollisionOption.OpenIfExists)
            myPictureFiles = Await mySubFolder.GetFilesAsync()
            myFile = myPictureFiles(myIndex)
            Dim trimBmp = New BitmapImage
            trimBmp.SetSource(Await myPictureFiles(myIndex).OpenReadAsync)
            Image1.Source = trimBmp
            Rectangle1.Visibility = Windows.UI.Xaml.Visibility.Collapsed
            resultImage.Source = Nothing
            Button1.IsEnabled = False
            deleteButton.IsEnabled = True
　　　　　　　　　allDeleteButton.IsEnabled = True
        End If
    End Sub