WindowsとPhoneで設定をローミングするには？［ユニバーサルWindowsアプリ開発］：WinRT／Metro TIPS

Public Class RoamingOptionSettings
  Implements System.ComponentModel.INotifyPropertyChanged
  ' INotifyPropertyChangedインターフェースの実装は、データバインド先にプロパティの変化を伝えるため

  ' ローミングされる設定を読み書きするためのオブジェクト
  Private _settings As Windows.Storage.ApplicationDataContainer _
      = Windows.Storage.ApplicationData.Current.RoamingSettings

  ' ローミングされてきたときの処理をUIスレッドで行うためのCoreDispatcher
  Public Property CurrentDispatcher As Windows.UI.Core.CoreDispatcher

  Public Sub New()
#If DEBUG Then
    ' VS 2013のXAMLエディター内でインスタンス化されたときは何もしない
    If (Windows.ApplicationModel.DesignMode.DesignModeEnabled) Then Return
#End If

    ' 設定データがローミングされてきたときのイベントハンドラーをセットする
    AddHandler Windows.Storage.ApplicationData.Current.DataChanged, _
               AddressOf RoamingSettings_DataChanged
  End Sub

  ' 設定データがローミングされてきたときのイベントハンドラー
  Private Async Sub RoamingSettings_DataChanged(sender As ApplicationData, args As Object)
    If (CurrentDispatcher Is Nothing) Then ' コーディングミスにより未設定の場合は、例外を出す
      Throw New InvalidOperationException(
        "RoamingOptionSettingsのCurrentDispatcherプロパティを事前に設定してください。")
    End If

    ' プロパティに変更があったことをイベントでバインド先に通知する
    ' 注意：このメソッドは別スレッドで呼び出されるため、
    '       UIに影響を及ぼす操作はCoreDispatcherを使ってこのように書く必要がある
    Await CurrentDispatcher.RunAsync(
            Windows.UI.Core.CoreDispatcherPriority.Normal,
            Sub()
              OnPropertyChanged("BackgroundSetting")
            End Sub
          )
  End Sub


  ' UIにバインドするプロパティ（2つ）

  ' ローミング設定に保存されるプロパティ（背景色）
  Private Const BackgroundDefault As String = "Blue" ' 既定の色
  Public Property BackgroundSetting As String
    Get
      Return GetValue(Of String)(BackgroundDefault)
    End Get
    Set(value As String)
      SetValue(Of String)(value)
    End Set
  End Property

  ' ユーザーに提示する色名のリスト
  Private _colorNames As IReadOnlyList(Of String) _
    = New String() {"DarkRed", "Green", BackgroundDefault}
  Public ReadOnly Property ColorNames As IReadOnlyList(Of String)
    Get
      Return _colorNames
    End Get
  End Property


  ' 以下は、RoamingSettingsを読み書きし、また、バインド先へのイベントを発生させるための汎用メソッド

  Public Event PropertyChanged(sender As Object, e As PropertyChangedEventArgs) _
    Implements INotifyPropertyChanged.PropertyChanged

  Private Function GetValue(Of T)(defaultValue As T, _
                     <System.Runtime.CompilerServices.CallerMemberName> Optional key As String = "") As T

    If (Not _settings.Values.ContainsKey(key)) Then
      Return defaultValue
    End If

    Dim value As Object = _settings.Values(key)
    If (value Is Nothing) Then
      Return Nothing
    Else
      Return CType(value, T)
    End If
  End Function

  Private Sub SetValue(Of T)(newValue As T, _
                <System.Runtime.CompilerServices.CallerMemberName> Optional key As String = "")

    _settings.Values(key) = newValue
    OnPropertyChanged(key)
  End Sub

  Private Sub OnPropertyChanged(
    <System.Runtime.CompilerServices.CallerMemberName> Optional propertyName As String = Nothing)

    RaiseEvent PropertyChanged(Me, New System.ComponentModel.PropertyChangedEventArgs(propertyName))
  End Sub
End Class

Protected Overrides Sub OnLaunched(e As LaunchActivatedEventArgs)
  ……省略……
  If rootFrame Is Nothing Then

    ' UIスレッドのDispatcherをRoamingOptionSettingsに渡しておく必要がある
    DirectCast(Me.Resources("RoamingOptionSettings"), RoamingOptionSettings).CurrentDispatcher _
      = Windows.UI.Core.CoreWindow.GetForCurrentThread().Dispatcher

    rootFrame = New Frame()
    ……省略……