AutoMapperを使ってオブジェクト間のデータコピーを自動化するには？（基本編）：.NET TIPS

Public Class Person

  Public Property FirstName As String
  Public Property LastName As String

  Public Shared Function GetData() As IList(Of Person)
    Dim list = New List(Of Person)()
    ' ダミーのデータ（実際にはデータベースなどから取得してくると思ってほしい）
    list.Add(New Person() With {.LastName = "八洲", .FirstName = "未來"})
    list.Add(New Person() With {.LastName = "山本", .FirstName = "康彦"})
    list.Add(New Person() With {.LastName = "嶺", .FirstName = "阿室"})
    Return list
  End Function
End Class

Public Class PersonForDisplay
  Implements ComponentModel.INotifyPropertyChanged

  ' 公開するイベントハンドラー（INotifyPropertyChangedインターフェースの実装）
  Public Event PropertyChanged(sender As Object, e As ComponentModel.PropertyChangedEventArgs) _
    Implements ComponentModel.INotifyPropertyChanged.PropertyChanged
  Private Sub NotifyPropertyChanged(info As String)
    RaiseEvent PropertyChanged(Me, _
                               New System.ComponentModel.PropertyChangedEventArgs(info))
  End Sub

  ' FirstNameプロパティ
  ' 値に変化があったときにはPropertyChangedイベントハンドラーを発火させる
  Private _firstName As String
  Public Property FirstName As String
    Get
      Return _firstName
    End Get
    Set(value As String)
      If (String.Equals(_firstName, value)) Then
        Return
      End If
      _firstName = value
      NotifyPropertyChanged("FirstName")
      NotifyPropertyChanged("DisplayName")
    End Set
  End Property

  ' LastNameプロパティ
  ' 値に変化があったときにはPropertyChangedイベントハンドラーを発火させる
  Private _lastName As String
  Public Property LastName As String
    Get
      Return _lastName
    End Get
    Set(value As String)
      If (String.Equals(_lastName, value)) Then
        Return
      End If
      _lastName = value
      NotifyPropertyChanged("LastName")
      NotifyPropertyChanged("DisplayName")
    End Set
  End Property

  ' 画面に表示したいDisplayNameプロパティ
  Public ReadOnly Property DisplayName As String
    Get
      Return String.Format("{0} {1}", LastName, FirstName)
    End Get
  End Property
End Class

Public Class PersonsList
  Private _persons _
    As System.Collections.ObjectModel.ObservableCollection(Of PersonForDisplay) _
    = New System.Collections.ObjectModel.ObservableCollection(Of PersonForDisplay) _
            (New List(Of PersonForDisplay)())
  Public ReadOnly Property Persons _
      As System.Collections.ObjectModel.ObservableCollection(Of PersonForDisplay)
    Get
      Return _persons
    End Get
  End Property

  Public Sub New()
    ' デザイン時に表示するダミーデータを設定する
    ' ……省略……
  End Sub
End Class

' ロジックを呼び出してデータを取得する
Dim data As IList(Of Person) = Person.GetData()

' 表示用のコレクションを用意する
Dim personsList = New PersonsList()

' データを表示用のコレクションにコピーする（AutoMapper未使用）
For Each p As Person In data
  personsList.Persons.Add( _
    New PersonForDisplay() _
      With {
        .FirstName = p.FirstName,
        .LastName = p.LastName
      }
  )
  ' ここでは二つだけだが、一般にはうんざりするほどの代入文を書く
Next

' 表示用のコレクションをデータコンテキストにセット
Me.DataContext = personsList

' AutoMapperを使う（オブジェクトごと）
AutoMapper.Mapper.CreateMap(Of Person, PersonForDisplay)()
For Each p As Person In data
  personsList.Persons.Add( _
    AutoMapper.Mapper.Map(Of PersonForDisplay)(p))
Next

' AutoMapperを使う（コレクション丸ごと）
AutoMapper.Mapper.CreateMap(Of Person, PersonForDisplay)()
Dim items = AutoMapper.Mapper.Map(Of IList(Of PersonForDisplay))(data)
For Each item As PersonForDisplay In items
  personsList.Persons.Add(item)
Next