列挙体の値を任意の文字列に変換するには？［C#／VB］：.NET TIPS

' 列挙体の定義
Enum e
  a
  b
  c
End Enum

……省略……

Dim e1 = e.a

' 列挙子の名前「a」を得る
Dim memberName As String = e1.ToString() ' ⇒ a

' 変換テーブルを使って対応する文字列を得る
Dim table = New Dictionary(Of e, String) _
                From {{e.a, "A"}, {e.b, "B"}, {e.c, "C"}}
Dim relatedName As String = table(e1) ' ⇒ A

Imports System.Console

Public Enum JapaneseEraName1
  明治 = 1
  大正
  昭和
  平成
End Enum

Module Module1
  Sub Main()
    Dim era = JapaneseEraName1.平成
    Dim eraName As String = era.ToString()
    WriteLine(eraName)
    ' 出力：平成

    ' 全ての名前を得る
    Dim eraNames As String() = [Enum].GetNames(GetType(JapaneseEraName1))
    WriteLine(String.Join(", ", eraNames))
    ' 出力：明治, 大正, 昭和, 平成

#If DEBUG Then
    ReadKey()
#End If
  End Sub
End Module

Public Enum JapaneseEraName2
  Meiji = 1868
  Taisho = 1912
  Showa = 1926
  Heisei = 1989
End Enum

……省略……

' JapaneseEraName2の値を元号の正式名称へ変換するためのテーブル
Private EraFullNames2 As New Dictionary(Of JapaneseEraName2, String) _
  From
  {
    {JapaneseEraName2.Meiji, "明治"},
    {JapaneseEraName2.Taisho, "大正"},
    {JapaneseEraName2.Showa, "昭和"},
    {JapaneseEraName2.Heisei, "平成"}
  }

' JapaneseEraName2の値を元号の略称へ変換するためのテーブル
Private EraShortNames2 As New Dictionary(Of JapaneseEraName2, String) _
  From
  {
    {JapaneseEraName2.Meiji, "M"},
    {JapaneseEraName2.Taisho, "T"},
    {JapaneseEraName2.Showa, "S"},
    {JapaneseEraName2.Heisei, "H"}
  }

……省略……

Dim era = JapaneseEraName2.Heisei
Dim eraFullName As String = EraFullNames2(era)
Dim eraShortName As String = EraShortNames2(era)
WriteLine($"{eraFullName}({eraShortName})")
' 出力：平成(H)

' 全ての略称を得る
Dim shortNames As IEnumerable(Of String) _
  = [Enum].GetValues(GetType(JapaneseEraName2)) _
          .Cast(Of JapaneseEraName2)() _
          .Select(Function(e) EraShortNames2(e))
WriteLine(String.Join(", ", shortNames))
' 出力：M, T, S, H

' 列挙体JapaneseEraName2の定義は前のサンプルコードと同じなので省略

Public Module JapaneseEraName2Extension
  ' JapaneseEraName2の値を元号の正式名称へ変換するためのテーブル
  Private EraFullNames2 As New Dictionary(Of JapaneseEraName2, String) _
    From
    {
      {JapaneseEraName2.Meiji, "明治"},
      {JapaneseEraName2.Taisho, "大正"},
      {JapaneseEraName2.Showa, "昭和"},
      {JapaneseEraName2.Heisei, "平成"}
    }

  ' JapaneseEraName2の値を元号の正式名称へ変換する拡張メソッド
  <System.Runtime.CompilerServices.Extension()>
  Public Function ToFullName(era As JapaneseEraName2) As String
    Return EraFullNames2(era)
  End Function

  ' JapaneseEraName2の値を元号の略称へ変換するためのテーブル
  Private EraShortNames2 As New Dictionary(Of JapaneseEraName2, String) _
    From
    {
      {JapaneseEraName2.Meiji, "M"},
      {JapaneseEraName2.Taisho, "T"},
      {JapaneseEraName2.Showa, "S"},
      {JapaneseEraName2.Heisei, "H"}
    }

  ' JapaneseEraName2の値を元号の略称へ変換する拡張メソッド
  <System.Runtime.CompilerServices.Extension()>
  Public Function ToShortName(era As JapaneseEraName2) As String
    Return EraShortNames2(era)
  End Function

End Module

……省略……

Dim era = JapaneseEraName2.Heisei
Dim eraFullName As String = era.ToFullName()
Dim eraShortName As String = era.ToShortName()
WriteLine($"{eraFullName}({eraShortName})")
' 出力：平成(H)

Public Enum JapaneseEraName3
  Meiji
  Taisho
  Showa
  Heisei
End Enum

……省略……

' JapaneseEraName3の値をインデックスとする元号の正式名称の配列
Private EraFullNames3 As String() = {"明治", "大正", "昭和", "平成"}
' JapaneseEraName3の値をインデックスとする元号の略称の配列
Private EraShortNames3 As String() = {"M", "T", "S", "H"}

……省略……

Dim era = JapaneseEraName3.Heisei
Dim eraFullName As String = EraFullNames3(era)
Dim eraShortName As String = EraShortNames3(era)
WriteLine($"{eraFullName}({eraShortName})")
' 出力：平成(H)