メンテナンス性や実行時間を改善――複数のExcelデータを1箇所に集約するマクロの別解とは：働く価値を上げる“VBA／GAS”術（9）（2/3 ページ）

Enum e
　　日付 = 1
　　科目
　　訪問先名
　　支払先名
　　内容
　　金額
　　備考
End Enum
　
Sub 経費データ収集()
Dim fso As FileSystemObject
Set fso = New FileSystemObject
Dim pass As String
pass = ThisWorkbook.Path & "\経費精算書"
Dim month As Date, department As String, fullname As String '対象月,部署,氏名
　
Dim rowsSheet1 As ListRows
Set rowsSheet1 = Sheet1.ListObjects(1).ListRows
　
Dim f As file
For Each f In fso.GetFolder(pass).Files
　　With Workbooks.Open(f)
　　　　With .Worksheets(1)
　　　　　　month = .Range("G1").Value　　　'対象月
　　　　　　department = .Range("G3").Value '部署
　　　　　　fullname = .Range("G4").Value　 '氏名
　　　　　　
　　　　　　With .ListObjects(1)
　　　　　　　　Dim row As ListRow
　　　　　　　　For Each row In .ListRows
　
　　　　　　　　　　Dim rowSheet1 As ListRow
　　　　　　　　　　Set rowSheet1 = rowsSheet1.Add
　
　　　　　　　　　　Dim rng As Range
　　　　　　　　　　Set rng = row.Range
　　　　　　　　　　rowSheet1.Range = Array( _
　　　　　　　　　　　　month, _
　　　　　　　　　　　　rng(e.日付), _
　　　　　　　　　　　　department, _
　　　　　　　　　　　　fullname, _
　　　　　　　　　　　　rng(e.科目), _
　　　　　　　　　　　　rng(e.内容), _
　　　　　　　　　　　　rng(e.金額), _
　　　　　　　　　　　　rng(e.備考) _
　　　　　　　　　　)
　　　　　　　　Next row
　　　　　　End With
　　　　End With
　　　　.Close
　　End With
Next f
Set fso = Nothing
　
End Sub