電子メールを送信するには？（outlook.com編）［.NET 4.5、C#／VB］：.NET TIPS

Imports System.Console
Imports System.Net.Http
Imports System.Net.Http.Headers
Imports Microsoft.Graph
Imports Microsoft.Identity.Client

Module Module1
  ' ClientIDには、アプリを登録したときのアプリケーションIDを設定する
  Const ClientID As String = "********-****-****-****-************"
  Private ReadOnly RedirectUri As String = $"msal{ClientID}://auth"

  ' ユーザー認証関係のプロパティ
  Public ReadOnly Property PCA As PublicClientApplication _
    = New PublicClientApplication(ClientID) With {.RedirectUri = RedirectUri}
  Public ReadOnly Property Scopes As IReadOnlyList(Of String) _
    = New List(Of String) From {"User.Read", "Mail.Send"}.AsReadOnly()

  Sub Main()
    Task.Run(Async Function() As Task
               Await SendMailAsync()
             End Function).Wait()
#If DEBUG Then
    ReadKey()
#End If
  End Sub
  Async Function SendMailAsync() As Task
    Dim ar As AuthenticationResult = Nothing ' 認証結果（アクセストークンなどが入る）
    Try
      ' まずサイレントサインインを試す
      Try
        Dim signedInUser As IAccount _
          = (Await PCA.GetAccountsAsync()).FirstOrDefault()
        If (signedInUser IsNot Nothing) Then
          ar = Await PCA.AcquireTokenSilentAsync(Scopes, signedInUser)
          ' サイレントサインインに失敗するとMsalUiRequiredExceptionが出る
        End If
      Catch
      End Try

      ' サイレントサインインができなかったら、サインインのUIを出す
      If (ar Is Nothing) Then
        ar = Await PCA.AcquireTokenAsync(Scopes)
      End If

      WriteLine("サインインしました。")
      WriteLine($"AccessToken={ar.AccessToken}")
      WriteLine($"Username={ar.Account.Username}")
      WriteLine($"ExpiresOn={ar.ExpiresOn.LocalDateTime.ToString("HH:mm:ss")}")
      WriteLine($"Scopes={String.Join(", ", ar.Scopes)}")
      ' 出力例：
      ' サインインしました。
      ' AccessToken=EwBwA8l6BAAURSN……中略……Rd2Ag==
      ' Username=biac@***.com
      ' ExpiresOn=23:02:13
      ' Scopes=mail.send, openid, profile, user.read
    Catch ex As MsalException
      ' 認証せずにダイアログを閉じると例外が出る
      WriteLine($"{ex.GetType().Name}:{ex.ErrorCode}")
    Catch ex As Exception
      WriteLine(ex.ToString())
    End Try
    If (ar Is Nothing) Then
      ' サインインできなかったのでアプリ終了
      Return
    End If

    ' ここでGraph APIを使った処理を行う

    ' サインアウトする
    Await PCA.RemoveAsync(ar.Account)
    WriteLine("サインアウトしました")
  End Function
End Module

' メール作成
Dim email = New Message With
{
  .ToRecipients = {
    New Recipient With {
      .EmailAddress = New EmailAddress With {
        .Name = "outlook.comからメール受信",
        .Address = "***@***.jp"
      }
    }
  },
  .Subject = "Graph APIでメールを送信するテスト",
  .Body = New ItemBody With
  {
    .ContentType = BodyType.Text,
    .Content = "Microsoft GRAPH を使ったメール送信のテスト。"
  }
}
' CC（CcRecipientsプロパティ）／BCC（BccRecipientsプロパティ）も指定可
' Recipientオブジェクトは複数指定可能（TO／CC／BCC）

Public Class MsalAuthenticationProvider
  Implements IAuthenticationProvider

  Public Async Function AuthenticateRequestAsync(request As HttpRequestMessage) As Task _
    Implements IAuthenticationProvider.AuthenticateRequestAsync

    ' 確実に有効なアクセストークンを得るために、サイレントサインインを行う
    Dim signedInUser As IAccount = (Await PCA.GetAccountsAsync()).FirstOrDefault()
    Dim ar As AuthenticationResult _
      = Await PCA.AcquireTokenSilentAsync(Scopes, signedInUser)

    ' アクセストークンをrequestにセットする
    request.Headers.Authorization _
      = New AuthenticationHeaderValue("Bearer", ar.AccessToken)
  End Function
End Class

' メール送信
Try
  Dim gsc As GraphServiceClient _
    = New GraphServiceClient(New MsalAuthenticationProvider())
  Await gsc.Me.SendMail(email).Request().PostAsync()
  WriteLine("メール送信完了")

Catch ex As Exception
  WriteLine("メール送信失敗")
  WriteLine(ex.ToString())
End Try

email.Attachments = New MessageAttachmentsCollectionPage()
Dim path As String = "C:\Windows\Web\Wallpaper\Theme2\img10.jpg" ' 添付したいファイル
email.Attachments.Add(New FileAttachment With
{
  .ODataType = "#microsoft.graph.fileAttachment",
  .ContentBytes = System.IO.File.ReadAllBytes(path),
  .ContentType = "image/jpeg",
  .Name = System.IO.Path.GetFileName(path)
})