フォームの閉じ方

' フォーム
Public Class SampleForm
    Public Event OpenButtonClicked As EventHandler
    Public Event CancelButtonClicked As EventHandler

    Private Sub OpenButton_Click(ByVal sender As Object, ByVal e As EventArgs) _
    Handles OpenButton.Click
        RaiseEvent OpenButtonClicked(Me, e)
    End Sub

    Private Sub CancelButton_Click(ByVal sender As Object, ByVal e As EventArgs) _
    Handles CancelButton.Click
        RaiseEvent CancelButtonClicked(Me, e)
    End Sub
End Class

' 親クラス
Public Class Class1
    Private WithEvents Form1 As SampleForm = New SampleForm
    Private WithEvents Form2 As SampleForm = New SampleForm
    Private WithEvents Form3 As SampleForm = New SampleForm

    Public Shared Sub Main()
        Dim c1 As Class1 = New Class1
        c1.Start()
    End Sub

    Private Sub Start()
        Application.EnableVisualStyles()
        Form1.Text = "Form1"
        Form2.Text = "Form2"
        Form3.Text = "Form3"
        Form3.OpenButton.Visible = False
        Form1.Show()
        Application.Run()
    End Sub

    Private Sub [Exit]()
        Form1.Dispose()
        Form2.Dispose()
        Form3.Dispose()
        Application.Exit()
    End Sub

    Private Sub Form1_FormClosing(ByVal sender As Object, ByVal e As FormClosingEventArgs) _
    Handles Form1.FormClosing, Form2.FormClosing, Form3.FormClosing
        If e.CloseReason.Equals(CloseReason.UserClosing) Then
            Me.Exit()
        End If
    End Sub

    Private Sub Form1_OpenButtonClicked(ByVal sender As Object, ByVal e As EventArgs) _
    Handles Form1.OpenButtonClicked, Form2.OpenButtonClicked, Form3.OpenButtonClicked
        If sender Is Form1 Then
            Form1.Hide()
            Form2.Show()
        ElseIf sender Is Form2 Then
            Form2.Hide()
            Form3.Show()
        End If
    End Sub

    Private Sub Form1_CancelButtonClicked(ByVal sender As Object, ByVal e As EventArgs) _
    Handles Form1.CancelButtonClicked, Form2.CancelButtonClicked, Form3.CancelButtonClicked
        If sender Is Form1 Then
            Me.Exit()
        ElseIf sender Is Form2 Then
            Form2.Hide()
            Form1.Show()
        ElseIf sender Is Form3 Then
            Form3.Hide()
            Form2.Show()
        End If
    End Sub
End Class