第7回 WshShellオブジェクトの詳細(3)Windows管理者のためのWindows Script Host入門(2/3 ページ)

» 2004年10月21日 00時00分 公開

レジストリからの値の取得 ―― RegReadメソッド ――

 RegReadメソッドはレジストリの値を取得するメソッドである。パラメータとしてレジストリのパスを指定すれば、対応する値を読み込むことができる。

1: Set objShell = WScript.CreateObject("WScript.Shell")
2: WScript.Echo objShell.RegRead("HKCR\.html\Content Type")
3: WScript.Echo objShell.RegRead("HKCR\.html\")
4: WScript.Echo objShell.ExpandEnvironmentStrings( objShell.RegRead( _
  "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\WallPaperDir") )

 4行目の例では、レジストリ値「WallPaperDir」の値は「%SystemRoot%\Web\Wallpaper」であり、この実行結果をExpandEnvironmentStringsメソッドのパラメータとして与えることにより、環境変数が展開され、最終的に「C:\WINDOWS\Web\Wallpaper」が得られる。全体の実行結果は次のようになる。

D:\WSH> cscript regread.vbs
text/html
htmlfile
C:\WINDOWS\Web\Wallpaper

D:\WSH>

 REG_MULTI_SZ型やREG_BINARY型の値は配列なので、For Each文などで処理する。

1: Set objShell = WScript.CreateObject("WScript.Shell")
2: colEventSource = objShell.RegRead _
3:   ("HKLM\SYSTEM\CurrentControlSet\Services\EventLog\Application
\Sources")
4:
5: For Each strSrc In colEventSource
6:   If Left(strSrc,1) = "W" Then
7:     WScript.Echo strSrc
8:   End If
9: Next

 2〜3行目で指定している「HKLM\SYSTEM\CurrentControlSet\Services\EventLog\Application\Sources」には、アプリケーション・イベント・ログにデータを書き込んだアプリケーションの一覧が保存されている。これを変数colEventSourceに代入し、For Each文で1つずつ処理を行う。筆者の環境で試したところ、一覧には多数のアプリケーションが記録されていたので、ここでは1文字目が「W」の場合だけ画面に出力することにした。実行結果は次のようになった。

D:\WSH> cscript regread.vbs
WSH
WMIAdapter
WmdmPmSN
WinMgmt
Winlogon
Windows Product Activation
Windows 3.1 Migration
Website Installer
WebClient
WebClassRuntime
W3Ctrs

D:\WSH>

 1行目に「WSH」が出力されているが、これは先ほどの例で、WSHからアプリケーション・イベント・ログに書き込みを行っていたために表示されたものだ。イベント・ログを利用することにより、イベント・ログ向けにサポートされる各種機能が使えると前述したが、これはその具体例の1つになっている。

レジストリへのデータの書き込み ―― RegWriteメソッド ――

 レジストリに値を書き込むにはRegWriteメソッドを使う。データを書き込みたいレジストリのパスと書き込む値をパラメータに指定する。このとき、すでに値が存在していれば、指定した値で更新され、存在していなければ新しい値として追加される。一般的な文字列値(REG_SZ)や整数値(REG_DWORD)はこの方法で書き込める。レジストリに保存されるデータのほとんどはこのいずれかなので、通常の処理ならRegWriteメソッドだけでも問題なく実行できるだろう。

 RegWriteメソッドでは、REG_MULTI_SZ(文字列配列)の値やREG_BINARY(2進数)値などは書き込めない。これらの値を書き込みたければ、レジストリ・エディタやReg.exeを呼び出して変更を行う方法をとる(詳細は後述する)。

 ここで注意点を1つ。レジストリに保存されたデータは、アプリケーションやOSが挙動のよりどころとしている重要な情報であり、間違った値を書き込むと、システムが正しく機能しなくなったり、不安定になったり、最悪の場合は起動不能に陥る危険もある。レジストリへの書き込みは、くれぐれも注意して行わなければならない。特に重要なサーバに対して実行する場合、多数のクライアントにスクリプトを展開する場合などは、万一事故が発生した場合の影響が大きいので特に注意が必要だ。十分にテストしてから展開するように心懸けたい。

 まずは例として、HKEY_CURRENT_USERの下に「WshTest」というキーを作り、いくつか値を書き込んでみよう。

1: Set objShell = WScript.CreateObject("WScript.Shell")
2: objShell.RegWrite "HKCU\WshTest\Test1", "Test #1"
3: objShell.RegWrite "HKCU\WshTest\Test2", 2
4: objShell.RegWrite "HKCU\WshTest\Test3", "Test #3", "REG_SZ"
5: objShell.RegWrite "HKCU\WshTest\Test4", 4, "REG_DWORD"
6: objShell.RegWrite "HKCU\WshTest\Test5", "%SystemRoot% #5", "REG_EXPAND_SZ"
7: objShell.RegWrite "HKCU\WshTest\", "Test #6", "REG_SZ"

 RegWriteメソッドの最初のパラメータにはレジストリのパスを、2番目のパラメータには書き込む値を、3番目のパラメータには書き込む値の型をそれぞれ指定する。このうち第3パラメータは省略可能で、省略した場合にはREG_SZ(文字列)型として書き込みが行われる。

 このコードは実行しても画面には何も表示されないので、書き込みが正しく行われたかどうかを調べるために[スタート]メニューの「ファイル名を指定して実行」に「regedit」と入力し、レジストリ・エディタを起動して結果を確認してみよう。

レジストリ・エディタでの確認
スクリプトで指定した「WshTest」キーが作成され、各値が書き込まれている。
 (1)作成されたキー。
 (2)追加された値。

 Test1とTest2は型を省略して書き込みを行ったので(2〜3行目)、REG_SZ(文字列)型として書き込みが行われた。Test2のように整数の値を書き込んでも、型はREG_SZ型となってしまうので注意が必要だ。Test3、Test4、Test5ではそれぞれREG_SZ(文字列)型、REG_DWORD(整数)型、REG_EXPAND_SZ(展開可能な文字列)型で書き込みが行われている。最後の書き込みはパスが「\」で終わっており、「(既定)」の値が設定された。

■特殊なデータ型での書き込み
 REG_BINARY(2進数)値は、1byte、2bytes、4bytesの値のみ書き込める。最終的に何バイト書き込まれるかは、設定する値に指定されているVBScriptの型によって変化する。通常の整数は2bytesなので、書き込みも2bytesで行われる。

 1byteや4bytesで書き込みたければ、パラメータに指定する値をそれぞれByte型やLong型に変換してRegWriteメソッドに渡すことで書き込める。ただし、これ以外のバイト数の場合には書き込むことができず、また、2bytes、4bytseの場合には書き込む場合と読み込む場合でバイト順序(バイト・オーダー)が逆転するなどの問題があるため、あまり使いやすいとはいえない。

 REG_MULTI_SZ(文字列の配列)の値やREG_BINARY値をスクリプトから書き込む場合には、RegWriteメソッドで直接書き込むのではなく、あらかじめレジストリ・エディタの[ファイル]−[エクスポート]でレジストリ・ファイル(拡張子 .reg)を作成し、この.regファイルに書き込みたいデータを設定してから、スクリプトでレジストリ・エディタを呼び出して値を変更する方法もある。スクリプトからレジストリ・エディタを起動するには次のようになる。

1: Set objShell = WScript.CreateObject("WScript.Shell")
2: objShell.Run "regedit /s data.reg"

 regeditによる書き込みでは、通常は「情報をレジストリに追加しますか?」「入力されました」といったメッセージが表示されるが、このように「/s」オプションを付けることで、これらを非表示にできる。

 またWindows XPとWindows Server 2003なら、Reg.exeというコマンドライン・ツールも利用できる。次は、これを使ってREG_MULTI_SZ値やREG_BINARY値を書き込む例である。

 1: Set objShell = WScript.CreateObject("WScript.Shell")
 2: objShell.Exec "reg add HKCU\WshTest /v Test7 /t REG_BINARY /d deadbeef1234 /f"
 3: ' キー HKCU\WshTest
 4: ' 値の名前(/v) Test7
 5: ' 型(/t) REG_BINARY
 6: ' 値(/d) deadbeef1234(16進表記)
 7: objShell.Exec "reg add HKCU\WshTest /ve /t REG_MULTI_SZ /s , /d abc,def,ghi /f"
 8: ' キー HKCU\WshTest
 9: ' 値の名前(/ve) なし(既定の値)
10: ' 型(/t) REG_MULTI_SZ
11: ' 区切り文字(/s) 「,」
12: ' 値(/d) 「abc」「def」「ghi」

 このようにReg.exeでは、書き込み先のレジストリ・キー、値、型、データをオプションとして指定できるようになっている。

レジストリ項目の削除 ―― RegDeleteメソッド ――

 レジストリの項目を削除するにはRegDeleteメソッドを利用する。RegDeleteメソッドでは、1つ1つの値を削除することも、キー全体を削除することもできる。キーを削除する場合にはパスの末尾に「\」を付け、値を削除する場合には「\」は付けない。キーを削除した場合はその下の値はすべて削除されるが、サブ・キーが存在した場合にはエラーとなって削除処理全体がキャンセルされる。また調べたところでは、既定の値だけを指定して削除する手段は提供されていないようだ。

 次の例では、WshTestキーの値Test1を削除する。

1: Set objShell = WScript.CreateObject("WScript.Shell")
2: objShell.RegDelete "HKCU\WshTest\Test1"

 このコードを実行してレジストリ・エディタで確認すれば、「Test1」の値がなくなっていることが分かる。また、WshTestキー全体を削除するには次のようにする。

1: Set objShell = WScript.CreateObject("WScript.Shell")
2: objShell.RegDelete "HKCU\WshTest\"

  

Copyright© Digital Advantage Corp. All Rights Reserved.

RSSについて

アイティメディアIDについて

メールマガジン登録

@ITのメールマガジンは、 もちろん、すべて無料です。ぜひメールマガジンをご購読ください。