第10回 WScriptオブジェクトを利用する(1)基礎解説 演習方式で身につけるチェック式WSH超入門(3/3 ページ)

» 2007年05月17日 00時00分 公開
前のページへ 1|2|3       

名前付きと名前なし引数――NamedとUnnamedプロパティ

 以上でWshArgumentsオブジェクトの基本的な使い方はお分かりいただけたと思う。しかしWshArgumentsオブジェクトには、より高度な使い方が存在する。

 WshArgumentsオブジェクトにはNamedプロパティとUnnamedプロパティが存在し、それぞれWshNamedコレクションおよびWshUnnamedコレクションを返す。これらは、コマンドライン引数のうち名前付きのもの、および、名前なしのものに対応する。WSHにおける名前付きの引数、名前なしの引数とは次のようなものである。

WSHにおける名前付き引数と名前なし引数
コマンドライン引数には名前付き引数(値のあるものとないもの)と名前なし引数が存在する。

 この例では「/param1」と「/param2:value2」と「param3」の3つのコマンドライン引数が存在する。「/(スラッシュ)」から始まる「/param1」は名前付き引数であり、「param1」が引数名である。同じく「/」から始まり、「:(コロン)」を含む「/param2:value2」は名前付き引数であり、「param2」が引数名、「value2」が値である。「/」のない「param3」は名前なし引数である。どれも引数であることに変わりないので、先ほどまでの例のようにWshArgumentsコレクションで取得できるが、それとは別に、名前付き引数と名前なし引数を分けてそれぞれにアクセスすることができる。それがWshNamedコレクションおよびWshUnnamedコレクションだ。これらの引数にアクセスするためのスクリプトを示そう。

※ファイル:ShowParameter2.vbs

Option Explicit

'オブジェクト変数の宣言と代入
Dim objWshNamed, objWshUnnamed
Set objWshNamed = WScript.Arguments.Named
Set objWshUnnamed = WScript.Arguments.Unnamed

'名前付き引数の存在有無を確認
If objWshNamed.Exists("param1") Then
    WScript.Echo "名前付き引数/param1が指定されました。"
End If

'名前付き引数の存在有無を確認し、その値を表示
If objWshNamed.Exists("param2") Then
    WScript.Echo "名前付き引数/param2が指定されました。", _
                 "その値は" & objWshNamed.Item("param2") & "です。"
End If

'名前なし引数の列挙
Dim intIndex
If objWshUnnamed.Count > 0 Then
    For intIndex = 0 To objWshUnnamed.Count - 1
        WScript.Echo "名前なし引数" & objWshUnnamed.Item(intIndex) & "が指定されました。"
    Next
End If

'オブジェクトの破棄
Set objWshNamed = Nothing
Set objWshUnnamed = Nothing

 このスクリプト<ShowParameter2.vbs>を先ほどの例のように「cscript.exe ShowParameter2.vbs /param1 /param2:value2 param3」として実行すると次のようになる。

名前付き引数および名前なし引数を指定してスクリプトを実行
WshNamedオブジェクトとWshUnnamedオブジェクトにより、名前付き引数および名前なし引数にアクセスが可能となる。

 少し難しくなったが順を追って説明しよう。まず、WScript.ArgumentsでWshArgumentsオブジェクトが取得できるが、さらに.(ドット)をつなげ、NamedおよびUnnamedプロパティを参照している。これらの値はWshNamedオブジェクト(コレクション)およびWshUnnamedオブジェクト(コレクション)であり、いずれもオブジェクトなので、変数に代入する際はSetステートメントを用いる。

 WshNamedコレクションには名前付き引数が格納されている。あるコマンドライン引数名が実際に指定されたかどうかを調べるのにはExistsメソッドを用いる。Existsメソッドは引数に指定したコマンドライン引数名が存在しているとTrue、存在していないとFalseを返す。ここでは、引数名param1および引数名param2が存在していればその旨を表示するようにしている。

 WshNamedコレクションはItemプロパティにインデックスとなる番号を引数に指定して要素を取り出すのではなく、コマンドライン引数名を引数に指定して、その値を取り出す。ここでは引数param2の値value2を取り出している。

 WshUnnamedコレクションはItemプロパティにインデックスとなる番号を指定して各要素を取り出すことができる。インデックスの最大値はCountメソッドの戻り値より1つ少ないことに注意して、For〜Nextステートメントを用いる。WshUnnamedコレクションはコレクションなので、For Each〜Nextステートメントを用いて名前なし引数を列挙することも可能だ。

 オブジェクトが多数登場したので混乱するといけないので、それらの階層構造と、この例においてプロパティに実際にどのような値が格納されているのかを図にしてみた。

WScript/WshArguments/WshNamed/WshUnnamedオブジェクトの階層図
これらのオブジェクトは図のような階層構造を形成している。

 さて、このようなWshNamedコレクションでアクセスできる名前付き引数の活用方法だが、複数の異なった意味を持つ引数を渡したいときに使うと便利である。例えば、台形の面積を求め、表示するスクリプトGetTrapezoidArea.vbsを作ってみよう。台形の面積は「(上底+下底)×高さ÷2」で求められるので、上底、下底、高さをコマンドライン引数に与えるとよい。引数名はそれぞれ上底を「a」、下底を「b」、高さを「h」とする。

CHECK!

マーカーで隠れたところを選択してチェックしてみよう。


※ファイル:GetTrapezoidArea.vbs

Option Explicit

'オブジェクト変数の宣言と代入
Dim objWshNamed
Set objWshNamed = WScript.Arguments.Named

'上底、下底、高さ、面積を格納する変数宣言と初期値設定
Dim dblUpperLength,dblLowerLength,dblHeight,dblArea
dblUpperLength = 0
dblLowerLength = 0
dblHeight = 0
dblArea = 0

'もし、引数a、b、hが存在していれば面積を計算する。
If objWshNamed.Exists("a") And _
   objWshNamed.Exists("b") And _
   objWshNamed.Exists("h") Then

        'もし引数aが数値なら その値をDouble型に変換し変数dblUpperLengthに格納
        If IsNumeric(objWshNamed("a")) Then dblUpperLength = CDbl(objWshNamed("a"))
        'もし引数bが数値なら その値をDouble型に変換し変数dblLowerLengthに格納
        If IsNumeric(objWshNamed("b")) Then dblLowerLength = CDbl(objWshNamed("b"))
        'もし引数hが数値なら その値をDouble型に変換し変数dblheightに格納
        If IsNumeric(objWshNamed("h")) Then dblheight = CDbl(objWshNamed("h"))

        '面積の計算
        dblArea = (dblUpperLength + dblLowerLength) * dblheight / 2

        '結果表示
        WScript.Echo "面積:", dblArea
Else '存在していなければ使い方を示す
        WScript.Echo "上底(a)、下底(b)、高さ(h)を指定してください。"
End If

 このスクリプトに例えばコマンドライン引数(上底1、下底2、高さ4)を付けて実行すると、面積が6と求まる。ここでポイントになるのは、「/h:4 /a:1 /b:2」のように引数の順番を変えても同じ結果が得られるところである。実行結果を示す。

台形の面積を求めるスクリプトの実行例
引数に指定された値を基に計算する。このように、名前付き引数を指定する順番は自由である。
 (1)結果1。面積は6。
 (2)結果2。やはり面積は6で、(1) と同じ。

 このため、名前付き引数を与えるようにしておくと、スクリプトを使う人がコマンドライン引数を与える順番を記憶しなくても、コマンドライン引数名だけを覚えていれば使用可能になるというメリットがあるということである。


 今回はWScriptオブジェクトのプロパティとメソッドの一部を紹介した。次回は残りのプロパティとメソッドを紹介する予定である。


「基礎解説 演習方式で身につけるチェック式WSH超入門」のインデックス

基礎解説 演習方式で身につけるチェック式WSH超入門

前のページへ 1|2|3       

Copyright© Digital Advantage Corp. All Rights Reserved.

RSSについて

アイティメディアIDについて

メールマガジン登録

@ITのメールマガジンは、 もちろん、すべて無料です。ぜひメールマガジンをご購読ください。